(Delphi DLL) HTTP GET -- Read Response from Stream

Demonstrates how to send an HTTP GET for a web page, and then read the response from a Stream. The purpose is to fulfill a situation such as the following: "I have a URL and just want the <head> </head> portion of the HTML. This would avoid having to download a potentially enormous web page just to get at header information, such as the <styles>."

Chilkat for Delphi Downloads

Chilkat non-ActiveX DLL for Delphi

Chilkat ActiveX DLL for Delphi

* The examples here use the non-ActiveX DLL.

uses
    Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
    Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Task, Rest, StringBuilder, Url, Stream;

...

procedure TForm1.Button1Click(Sender: TObject);
var
rest: HCkRest;
url: HCkUrl;
bAutoReconnect: Boolean;
success: Boolean;
responseStatusCode: Integer;
errResponse: PWideChar;
bodyStream: HCkStream;
readResponseBodyTask: HCkTask;
sbBody: HCkStringBuilder;
exitLoop: Boolean;
bodyText: PWideChar;
maxWaitMs: Integer;

begin
// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

rest := CkRest_Create();

// In this example, we'll get the web page at http://www.nytimes.com/pages/business/index.html
// The domain is "www.nytimes.com", and the path is "/pages/business/index.html"

// If we have only the full URL to begin with, it can be loaded into the Chilkat URL object to
// access the parts:
url := CkUrl_Create();
CkUrl_ParseUrl(url,'http://www.nytimes.com/pages/business/index.html');

bAutoReconnect := True;
success := CkRest_Connect(rest,CkUrl__host(url),CkUrl_getPort(url),CkUrl_getSsl(url),bAutoReconnect);

// Send the GET request (This sends the GET request, but does not read the response.)
success := CkRest_SendReqNoBody(rest,'GET',CkUrl__path(url));
if (success <> True) then
  begin
    Memo1.Lines.Add(CkRest__lastErrorText(rest));
    Exit;
  end;

// Read the response header.
responseStatusCode := CkRest_ReadResponseHeader(rest);
if (responseStatusCode < 0) then
  begin
    Memo1.Lines.Add(CkRest__lastErrorText(rest));
    Exit;
  end;

Memo1.Lines.Add('Response status code = ' + IntToStr(responseStatusCode));

// We expect a 200 response status.
if (responseStatusCode <> 200) then
  begin

    // If the response status code is not 200, we could check for a redirect status code and 
    // then follow it, read the entire response (as shown here), or just call rest.Disconnect
    errResponse := CkRest__readRespBodyString(rest);
    if (CkRest_getLastMethodSuccess(rest) <> True) then
      begin
        Memo1.Lines.Add(CkRest__lastErrorText(rest));
      end
    else
      begin
        Memo1.Lines.Add(errResponse);
      end;

    Exit;
  end;

bodyStream := CkStream_Create();
// Set a 10 second read timeout for the stream. 
// (Give up if no data arrives within 10 seconds after calling a read method.)
CkStream_putReadTimeoutMs(bodyStream,10000);

// Create a background thread task to read the response body (which feeds
// it to the bodyStream object.)
readResponseBodyTask := CkRest_ReadRespBodyStreamAsync(rest,bodyStream,True);

// Start the task. 
success := CkTask_Run(readResponseBodyTask);

// Read the HTTP response body until the "</head>" is seen, or until
// the end-of-stream is reached.

sbBody := CkStringBuilder_Create();
exitLoop := False;
while not exitLoop and (CkStream_getEndOfStream(bodyStream) <> True) do
  begin

    bodyText := CkStream__readString(bodyStream);
    if (CkStream_getLastMethodSuccess(bodyStream) = True) then
      begin
        CkStringBuilder_Append(sbBody,bodyText);
        if (CkStringBuilder_Contains(sbBody,'</head>',False)) then
          begin
            exitLoop := True;
          end;
      end
    else
      begin
        exitLoop := True;
      end;

  end;

// Cancel the remainder of the task...
CkTask_Cancel(readResponseBodyTask);

CkTask_Dispose(readResponseBodyTask);

// Ensure we're disconnected from the server.
maxWaitMs := 50;
CkRest_Disconnect(rest,maxWaitMs);

Memo1.Lines.Add('----');
Memo1.Lines.Add(CkStringBuilder__getAsString(sbBody));
Memo1.Lines.Add('----');
Memo1.Lines.Add('Successfully received the body up to the desired point.');

CkRest_Dispose(rest);
CkUrl_Dispose(url);
CkStream_Dispose(bodyStream);
CkStringBuilder_Dispose(sbBody);

end;