(VBScript) POP3 using HTTP Proxy

Demonstrates how to communicate with a POP3 server through an HTTP proxy.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' The mailman object is used for receiving (POP3) 
' and sending (SMTP) email.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.MailMan")
set mailman = CreateObject("Chilkat.MailMan")

' To connect through an HTTP proxy, set the HttpProxyHostname
' and HttpProxyPort properties to the hostname (or IP address)
' and port of the HTTP proxy.  Typical port numbers used by
' HTTP proxy servers are 3128 and 8080.
mailman.HttpProxyHostname = "www.my-http-proxy.com"
mailman.HttpProxyPort = 3128

' Important:  Your HTTP proxy server must allow non-HTTP
' traffic to pass.  Otherwise this does not work.

' Set the POP3 server's hostname
mailman.MailHost = "pop.someMailServer.com"

' Set the POP3 login/password.
mailman.PopUsername = "myLogin"
mailman.PopPassword = "myPassword"

' Copy the all email from the user's POP3 mailbox 
' into a bundle object.  The email remains on the server.
' 
' NOTE: All methods that communicate with a POP3 server
' will automatically connect and authenticate (i.e. login)
' if not already connected.  The connection will remain
' open after the method call returns so that subsequent
' calls do not need to re-establish the connection.
' In this case, the connection is established via the HTTP
' proxy.
' bundle is a Chilkat.EmailBundle
Set bundle = mailman.CopyMail()
If (mailman.LastMethodSuccess = 0) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

i = 0

Do While i < bundle.MessageCount
    ' email is a Chilkat.Email
    Set email = bundle.GetEmail(i)
    outFile.WriteLine("From: " & email.From)
    outFile.WriteLine("Subject: " & email.Subject)

    i = i + 1
Loop

success = mailman.Pop3EndSession()

outFile.Close