(VBScript) Async Methods Returning an Object

Demonstrates how to call an asynchronous method that returns an object. This example reads email from a POP3 server using the Async versions of the Chilkat methods.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' All Chilkat classes can be unlocked at once at the beginning of a program
' by calling UnlockBundle.  It requires a Bundle unlock code.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Global")
set chilkatGlob = CreateObject("Chilkat.Global")
success = chilkatGlob.UnlockBundle("Anything for 30-day trial.")
If (success <> 1) Then
    outFile.WriteLine(chilkatGlob.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.MailMan")
set mailman = CreateObject("Chilkat.MailMan")

' Set the POP3 server's hostname
mailman.MailHost = "pop.someMailServer.com"

' Set the POP3 login/password and any other requirements..
mailman.PopUsername = "myLogin"
mailman.PopPassword = "myPassword"
mailman.PopSsl = 1
mailman.MailPort = 995

' Connect to the POP3 server:
' task is a Chilkat.Task
Set task = mailman.Pop3BeginSessionAsync()
If (mailman.LastMethodSuccess = 0) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

' Start the background task.
success = task.Run()
If (Not success) Then
    outFile.WriteLine(task.LastErrorText)

    WScript.Quit
End If

' Wait for the POP3 connect task to finish.
' The 1/0 returned by Wait applies to the Wait method call, not the task.
maxWaitMs = 30000
success = task.Wait(maxWaitMs)
If (Not success Or (task.StatusInt <> 7) Or (task.TaskSuccess <> 1)) Then
    If (Not success) Then
        ' The task.LastErrorText applies to the Wait method call.
        outFile.WriteLine(task.LastErrorText)
    Else
        ' The ResultErrorText applies to the underlying task method call (i.e. the Pop3BeginSession)
        outFile.WriteLine(task.Status)
        outFile.WriteLine(task.ResultErrorText)
    End If

    WScript.Quit
End If

' Get the number of messages in the mailbox.
' task is a Chilkat.Task
Set task = mailman.GetMailboxCountAsync()

' To keep the example short, we'll skip handling failures.
' The failures would be handled in the same way as shown above.

success = task.Run()
success = task.Wait(maxWaitMs)
numMessages = task.GetResultInt()

If (numMessages = 0) Then
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Email")
set email = CreateObject("Chilkat.Email")

For i = 1 To numMessages

    ' task is a Chilkat.Task
    Set task = mailman.FetchByMsgnumAsync(i)
    If (mailman.LastMethodSuccess = 0) Then
        outFile.WriteLine(mailman.LastErrorText)
        WScript.Quit
    End If

    success = task.Run()
    success = task.Wait(maxWaitMs)
    If (Not success Or (task.StatusInt <> 7) Or (task.TaskSuccess <> 1)) Then
        If (Not success) Then
            ' The task.LastErrorText applies to the Wait method call.
            outFile.WriteLine(task.LastErrorText)
        Else
            ' The ResultErrorText applies to the underlying task method call (i.e. the FetchByMsgnum)
            outFile.WriteLine(task.Status)
            outFile.WriteLine(task.ResultErrorText)
        End If

        WScript.Quit
    End If

    ' Each Chilkat object that can be a return value of an asynchronous task will
    ' have a method named LoadTaskResult.  The object returned in the underlying
    ' asynchronous method call is retrieved by calling LoadTaskResult. 

    ' To say it another way: The application will provide a pre-existing object of
    ' the desired return type (in this case it is an email object).  This object is
    ' loaded by calling LoadTaskResult.  

    success = email.LoadTaskResult(task)

    If (Not success) Then
        outFile.WriteLine(email.LastErrorText)
        WScript.Quit
    Else
        outFile.WriteLine(email.From & ": " & email.Subject & vbLf)
    End If

Next

outFile.Close