(VB.NET) PayPal -- Get an OAuth 2.0 Access Token

Demonstrates how to send a request to get a PayPal OAuth2 access token. Sends an HTTP request equivalent to the following:

curl https://api.sandbox.paypal.com/v1/oauth2/token \
  -H "Accept: application/json" \
  -H "Accept-Language: en_US" \
  -u "Client-Id:Secret" \
  -d "grant_type=client_credentials"

Chilkat .NET Downloads Chilkat .NET Framework Chilkat for .NET Core

' Note: Requires Chilkat v9.5.0.64 or greater.

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim rest As New Chilkat.Rest

' Make the initial connection.
' A single REST object, once connected, can be used for many PayPal REST API calls.
' The auto-reconnect indicates that if the already-established HTTPS connection is closed,
' then it will be automatically re-established as needed.
Dim bAutoReconnect As Boolean = True
Dim success As Boolean = rest.Connect("api.sandbox.paypal.com",443,True,bAutoReconnect)
If (success <> True) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


' Duplicate this request:

' 	curl https://api.sandbox.paypal.com/v1/oauth2/token \
' 	  -H "Accept: application/json" \
' 	  -H "Accept-Language: en_US" \
' 	  -u "Client-Id:Secret" \
' 	  -d "grant_type=client_credentials"

rest.AddHeader("Accept","application/json")
rest.AddHeader("Accept-Language","en_US")

' For additional help on where to find  your client ID and API secret, see PayPal Client_ID and API_Secret
rest.SetAuthBasic("PAYPAL_REST_API_CLIENT_ID","PAYPAL_REST_API_SECRET")

rest.AddQueryParam("grant_type","client_credentials")

Dim responseStr As String = rest.FullRequestFormUrlEncoded("POST","/v1/oauth2/token")
If (rest.LastMethodSuccess <> True) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


Debug.WriteLine(rest.LastRequestHeader)

' A sample response:

' 	{
' 	  "scope": "https://api.paypal.com/v1/payments/.* https://api.paypal.com/v1/vault/credit-card https://api.paypal.com/v1/vault/credit-card/.*",
' 	  "access_token": "EEwJ6tF9x5WCIZDYzyZGaz6Khbw7raYRIBV_WxVvgmsG",
' 	  "token_type": "Bearer",
' 	  "app_id": "APP-6XR95014BA15863X",
' 	  "expires_in": 28800
' 	}

Dim json As New Chilkat.JsonObject
json.Load(responseStr)
json.EmitCompact = False

' Check the response status code.  A 200 indicates success..
If (rest.ResponseStatusCode <> 200) Then
    Debug.WriteLine(json.Emit())
    Debug.WriteLine("Failed.")
    Exit Sub
End If


' Given that the access token expires in approx 8 hours,
' let's record the date/time this token was created.
' This will allow us to know beforehand if the token
' is expired (and we can then fetch a new token).
Dim dateTime As New Chilkat.CkDateTime
Dim bLocalTime As Boolean = False
Dim dtNow As Integer = dateTime.GetAsUnixTime(bLocalTime)
json.AppendInt("tokenCreateTimeUtc",dtNow)

' Examine the access token and save to a file.
Debug.WriteLine("Access Token: " & json.StringOf("access_token"))
Debug.WriteLine("Full JSON Response:")
Debug.WriteLine(json.Emit())

Dim sbResponse As New Chilkat.StringBuilder
sbResponse.Append(json.Emit())
Dim bEmitBom As Boolean = False
sbResponse.WriteFile("qa_data/tokens/paypal.json","utf-8",bEmitBom)