(Visual Basic 6.0) XMP API Helps Build the XML

The Chilkat XMP API is helpful in making it easier to build the XML that comprises XMP. If an XMP API feature does not exist to create the desired XML structure, then the Chilkat XML API can be used. The important thing to notice is that all XMP methods that modify XML pass the XML to be modified in the 1st argument. Thus, the XMP methods are really just helper methods to do common tasks in creating/editing the XML.

This example shows how to create a bag with a more complicated structure -- something that is not automatically provided by the XMP API, but can easily be done using the XML API.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim xmp As New ChilkatXmp

Dim xml As ChilkatXml

' The first step is to create a new XMP document, which is nothing
' more than XML.  The NewXmp method returns an XML document with
' the standard XMP boilerplate.  
Set xml = xmp.NewXmp()

' Add some properties...
Dim success As Long
success = xmp.AddSimpleStr(xml,"Iptc4xmpCore:Chilkat","Blah blah")

' Now create a Bag.
Dim sa As New CkStringArray
success = sa.Append("value_1")
success = sa.Append("value_2")
' ...

' Notice the XML object is passed in the 1st argument.
' The XMP method is really just a higher-level means to create XML
' commonly needed for XMP.
success = xmp.AddArray(xml,"bag","Iptc4xmpExt:LocationCreated",sa)

' Let's examine the XML..
Debug.Print xml.GetXml()

' the bag looks like this:

'     <Iptc4xmpExt:LocationCreated>
'         <rdf:Bag>
'             <rdf:li>value_1</rdf:li>
'             <rdf:li>value_2</rdf:li>
'         </rdf:Bag>
'     </Iptc4xmpExt:LocationCreated>

' Let's say we really want this:

'  <Iptc4xmpExt:LocationCreated>
'    <rdf:Bag>
'     <rdf:li rdf:parseType='Resource'>
'      <Iptc4xmpExt:City>Ville création photo</Iptc4xmpExt:City>
'      <Iptc4xmpExt:CountryName>Nom diu pays de la photo</Iptc4xmpExt:CountryName>
'      <Iptc4xmpExt:ProvinceState>Département; Photo</Iptc4xmpExt:ProvinceState>
'      <Iptc4xmpExt:Sublocation>Lieu création photo</Iptc4xmpExt:Sublocation>
'     </rdf:li>
'    </rdf:Bag>
'   </Iptc4xmpExt:LocationCreated>

' No problem...  Let's just fix it.

Dim x As ChilkatXml
Set x = xml.SearchForTag(xml,"Iptc4xmpExt:LocationCreated")

' Assume it was found..
' Move to the rdf:Bag node
success = x.FirstChild2()

' Discard the existing <rdf:il> values..
x.RemoveAllChildren 

' Build the new XML in its place..
x.NewChild2 "rdf:li",""
success = x.AddAttribute("rdf:parseType","Resource")

' Move to the "rdf:li" node.
success = x.FirstChild2()
x.NewChild2 "Iptc4xmpExt:City","Ville création photo"
x.NewChild2 "Iptc4xmpExt:CountryName","Nom diu pays de la photo"
x.NewChild2 "Iptc4xmpExt:ProvinceState","Département; Photo"
x.NewChild2 "Iptc4xmpExt:Sublocation","Lieu création photo"

' Let's create another bag item..
' Move back up to the "rdf:Bag" node.
success = x.GetParent2()

x.NewChild2 "rdf:li",""
success = x.AddAttribute("rdf:parseType","Resource")

' Move to the newly added "rdf:li" node, which is the 2nd child (index = 1)
success = x.GetChild2(1)
x.NewChild2 "Iptc4xmpExt:City","2 Ville création photo"
x.NewChild2 "Iptc4xmpExt:CountryName","2 Nom diu pays de la photo"
x.NewChild2 "Iptc4xmpExt:ProvinceState","2 Département; Photo"
x.NewChild2 "Iptc4xmpExt:Sublocation","2 Lieu création photo"

' Let's examine the XML now...
Debug.Print xml.GetXml()