Visual Basic 6.0

Removing / Deleting Child Nodes from XML

See more XML Examples

Demonstrates various methods for removing child nodes from an XML document.

The input XML, available at http://www.chilkatsoft.com/data/fruit.xml, is this:

<root>
    <fruit color="red">apple</fruit>
    <fruit color="green">pear</fruit>
    <veg color="orange">carrot</veg>
    <meat animal="cow">beef</meat>
    <xyz>
        <fruit color="blue">blueberry</fruit>
        <veg color="green">broccoli</veg>
    </xyz>
    <fruit color="purple">grape</fruit>
    <cheese color="yellow">cheddar</cheese>
</root>

Visual Basic 6.0

Dim success As Long
success = 0

Dim xml As New ChilkatXml
Dim xyz As ChilkatXml

' The sample input XML is available at http://www.chilkatsoft.com/data/fruit.xml
success = xml.LoadXmlFile("fruit.xml")
If (success <> 1) Then
    Debug.Print xml.LastErrorText
    Exit Sub
End If

' The RemoveChild method removes (discards) all direct
' children having the specified tag:
xml.RemoveChild "fruit"

' Show the resulting XML:
Debug.Print "Result with all direct children having a tag equal to ""fruit"" removed:"
Debug.Print xml.GetXml()

' The XML with the "fruit" direct children removed is shown below:
' Notice that the "fruit" node beneath "xyz" was not removed.
' This correct because it was not a direct child of the calling node.

' <root>
'     <veg color="orange">carrot</veg>
'     <meat animal="cow">beef</meat>
'     <xyz>
'         <fruit color="blue">blueberry</fruit>
'         <veg color="green">broccoli</veg>
'     </xyz>
'     <cheese color="yellow">cheddar</cheese>
' </root>

' --------------------------------------------------------------------------
' Restore the original XML:
success = xml.LoadXmlFile("fruit.xml")

' The RemoveChildWithContent method removes the child
' having the exact content specified, regardless of the tag.  
' For example:
xml.RemoveChildWithContent "pear"

' Show the resulting XML:
Debug.Print "Result with the node containing ""pear"" removed:"
Debug.Print xml.GetXml()

' --------------------------------------------------------------------------
' Restore the original XML:
success = xml.LoadXmlFile("fruit.xml")

' The RemoveChildByIndex method removes the Nth direct
' child.  Indexing begins at 0.  The "xyz" child is at index 4:
xml.RemoveChildByIndex 4

' Show the resulting XML:
' Notice that the entire "xyz" subtree is removed.
Debug.Print "Result with the node at index 4 removed:"
Debug.Print xml.GetXml()

' --------------------------------------------------------------------------
' Restore the original XML:
success = xml.LoadXmlFile("fruit.xml")

' Navigate to the node with tag "xyz"
Set xyz = xml.FindChild("xyz")

' Remove the "xyz" subtree making it it's own XML document
' with the "xyz" node at the root:
xyz.RemoveFromTree 

' Show both XML documents:
Debug.Print xyz.GetXml()
Debug.Print xml.GetXml()

' Also, the TreeId property is an integer value assigned
' to nodes in an XML document.  All nodes belonging to
' the same XML document will have the same TreeId.
' Notice that the "xyz" node now has a different TreeId:
Debug.Print "xyz TreeId = " & xyz.TreeId
Debug.Print "xml TreeId = " & xml.TreeId