Visual Basic 6.0

WordPress Create Tag

See more WordPress Examples

Demonstrates how to create a new tag in Wordpress, or to find the ID of an existing tag. Visual Basic 6.0

Dim success As Long
success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim http As New ChilkatHttp

' Use your WordPress login, such as "admin", not the application name.
http.Login = "wp_username"
' Use the application password, such as "Nths RwVH eDJ4 weNZ orMN jabq"
' See WordPress Application Passwords Plugin
http.Password = "app_password"
http.BasicAuth = 1

' Create the tag "ChatGPT" if it does not already exist.
Dim json As New ChilkatJsonObject
success = json.UpdateString("name","ChatGPT")

' This will create the tag if it does not yet exist.
' If the tag already exists, then a 400 status code is returned.
' If the tag deoes not yet exist, then a 201 status code is returned.
Dim resp As New ChilkatHttpResponse
success = http.HttpJson("POST","https://cknotes.com/wp-json/wp/v2/tags",json,"application/json",resp)
If (success = 0) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

Dim jResp As New ChilkatJsonObject
success = jResp.Load(resp.BodyStr)

' Check if the tag already exists..
If (resp.StatusCode = 400) Then
    If (jResp.HasMember("code") = 1) Then
        If (jResp.StringOfEquals("code","term_exists",1) = 1) Then
            ' The tag already exists.
            Debug.Print "The tag already exists."
            Debug.Print "Tag ID: " & jResp.IntOf("data.term_id")
            Exit Sub
        End If

    End If

    ' Fall through to check for errors.
End If

' Check for errors.
If (resp.StatusCode <> 201) Then
    Debug.Print resp.BodyStr
    Debug.Print "status code = " & resp.StatusCode
    Exit Sub
End If

' We get here if the tag was created..
Debug.Print "The tag was created."
Debug.Print "Tag ID = " & jResp.IntOf("id")