Visual Basic 6.0

UPS Address Validation (City, State, Zip)

See more HTTP Misc Examples

Demonstrates making a call to the UPS address validation REST API. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim http As New ChilkatHttp

' This is the testing endpoint for address validation:
Dim url As String
url = "https://wwwcie.ups.com/rest/AV"

' Send an HTTP request with the following JSON body:

' {
'   "AccessRequest": {
'     "AccessLicenseNumber": "Your Access License Number",
'     "UserId": "Your Username",
'     "Password": "Your Password"
'   },
'   "AddressValidationRequest": {
'     "Request": {
'       "TransactionReference": {
'         "CustomerContext": "Your Customer Context"
'       },
'       "RequestAction": "AV"
'     },
'     "Address": {
'       "City": "ALPHARETTA",
'       "StateProvinceCode": "GA",
'       "PostalCode": "30005"
'     }
'   }
' }

' Build the above JSON.
Dim json As New ChilkatJsonObject
success = json.UpdateString("AccessRequest.AccessLicenseNumber","UPS_ACCESS_KEY")
success = json.UpdateString("AccessRequest.UserId","UPS_USERNAME")
success = json.UpdateString("AccessRequest.Password","UPS_PASSWORD")
success = json.UpdateString("AddressValidationRequest.Request.TransactionReference.CustomerContext","Your Customer Context")
success = json.UpdateString("AddressValidationRequest.Request.RequestAction","AV")
success = json.UpdateString("AddressValidationRequest.Address.City","ALPHARETTA")
' We're making an intentional mistake here by passing CA instead of GA.
success = json.UpdateString("AddressValidationRequest.Address.StateProvinceCode","CA")
success = json.UpdateString("AddressValidationRequest.Address.PostalCode","30005")

Dim sb As New ChilkatStringBuilder
Dim resp As New ChilkatHttpResponse
success = http.HttpJson("POST",url,json,"application/json",resp)
If (success = 0) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

Debug.Print "status = " & resp.StatusCode

' A 200 response status indicate success.
If (resp.StatusCode <> 200) Then
    Debug.Print resp.BodyStr
    Debug.Print "Failed."
    Exit Sub
End If

success = json.Load(resp.BodyStr)
json.EmitCompact = 0
Debug.Print json.Emit()

' A successful exact response looks like this:

' {
'   "AddressValidationResponse": {
'     "Response": {
'       "TransactionReference": {
'         "CustomerContext": "Your Customer Context"
'       },
'       "ResponseStatusCode": "1",
'       "ResponseStatusDescription": "Success"
'     },
'     "AddressValidationResult": {
'       "Rank": "1",
'       "Quality": "1.0",
'       "Address": {
'         "City": "ALPHARETTA",
'         "StateProvinceCode": "GA"
'       },
'       "PostalCodeLowEnd": "30005",
'       "PostalCodeHighEnd": "30005"
'     }
'   }
' }
' 

' A successful response that was not an exact match provides an array of closest matches, like this:

' {
'   "AddressValidationResponse": {
'     "Response": {
'       "TransactionReference": {
'         "CustomerContext": "Your Customer Context"
'         "Quality": "0.9875",
'         "Address": {
'       },
'       "ResponseStatusCode": "1",
'       "ResponseStatusDescription": "Success"
'     },
'     "AddressValidationResult": [
'       {
'         "Rank": "1",
'           "City": "ALPHARETTA",
'           "StateProvinceCode": "GA"
'         },
'         "PostalCodeLowEnd": "30005",
'         "PostalCodeHighEnd": "30005"
'       },
'       {
'         "Rank": "2",
'         "Quality": "0.9750",
'         "Address": {
'           "City": "ALPHARETTA",
'           "StateProvinceCode": "GA"
'         },
'         "PostalCodeLowEnd": "30004",
'         "PostalCodeHighEnd": "30004"
'       },
'       {
'         "Rank": "3",
'         "Quality": "0.9750",
'         "Address": {
'           "City": "ALPHARETTA",
'           "StateProvinceCode": "GA"
'         },
'         "PostalCodeLowEnd": "30009",
'         "PostalCodeHighEnd": "30009"
'       }
'     ]
'   }
' }

' Use the online tool at Generate JSON Parsing Code
' to generate JSON parsing code.

Dim customerContext As String
Dim statusCode As String
Dim statusDescription As String
Dim resultRank As String
Dim resultQuality As String
Dim city As String
Dim provinceCode As String
Dim postalCodeLowEnd As String
Dim postalCodeHighEnd As String
Dim rank As String
Dim quality As String
Dim addressCity As String
Dim addressStateProvinceCode As String

Dim numResults As Long
numResults = json.SizeOfArray("AddressValidationResponse.AddressValidationResult")
If (numResults < 0) Then

    ' Here's parse code for the above JSON exact response:
    customerContext = json.StringOf("AddressValidationResponse.Response.TransactionReference.CustomerContext")
    statusCode = json.StringOf("AddressValidationResponse.Response.ResponseStatusCode")
    statusDescription = json.StringOf("AddressValidationResponse.Response.ResponseStatusDescription")
    resultRank = json.StringOf("AddressValidationResponse.AddressValidationResult.Rank")
    resultQuality = json.StringOf("AddressValidationResponse.AddressValidationResult.Quality")
    city = json.StringOf("AddressValidationResponse.AddressValidationResult.Address.City")
    provinceCode = json.StringOf("AddressValidationResponse.AddressValidationResult.Address.StateProvinceCode")
    postalCodeLowEnd = json.StringOf("AddressValidationResponse.AddressValidationResult.PostalCodeLowEnd")
    postalCodeHighEnd = json.StringOf("AddressValidationResponse.AddressValidationResult.PostalCodeHighEnd")

    Debug.Print "Exact match!"
    Debug.Print "postal code: " & postalCodeLowEnd

Else

    Debug.Print "Non-Exact match."

    customerContext = json.StringOf("AddressValidationResponse.Response.TransactionReference.CustomerContext")
    statusCode = json.StringOf("AddressValidationResponse.Response.ResponseStatusCode")
    statusDescription = json.StringOf("AddressValidationResponse.Response.ResponseStatusDescription")
    Dim i As Long
    i = 0
    Do While i < numResults
        json.I = i
        rank = json.StringOf("AddressValidationResponse.AddressValidationResult[i].Rank")
        Debug.Print "rank: " & rank
        quality = json.StringOf("AddressValidationResponse.AddressValidationResult[i].Quality")
        addressCity = json.StringOf("AddressValidationResponse.AddressValidationResult[i].Address.City")
        Debug.Print "addressCity: " & addressCity
        addressStateProvinceCode = json.StringOf("AddressValidationResponse.AddressValidationResult[i].Address.StateProvinceCode")
        postalCodeLowEnd = json.StringOf("AddressValidationResponse.AddressValidationResult[i].PostalCodeLowEnd")
        Debug.Print "postal code: " & postalCodeLowEnd
        postalCodeHighEnd = json.StringOf("AddressValidationResponse.AddressValidationResult[i].PostalCodeHighEnd")
        i = i + 1
    Loop
End If