Visual Basic 6.0

SQS List Queues

See more Amazon SQS Examples

Returns a list of your Amazon SQS queues. The maximum number of queues that can be returned is 1000. If you specify a value for the optional QueueNamePrefix query parameter, only queues with a name beginning with the specified value are returned. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim rest As New ChilkatRest

' Connect to the Amazon AWS REST server.
' such as https://sqs.us-west-2.amazonaws.com/
Dim bTls As Long
bTls = 1
Dim port As Long
port = 443
Dim bAutoReconnect As Long
bAutoReconnect = 1
success = rest.Connect("sqs.us-west-2.amazonaws.com",port,bTls,bAutoReconnect)

' Provide AWS credentials for the REST call.
Dim authAws As New ChilkatAuthAws
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
' the region should match our URL above..
authAws.Region = "us-west-2"
authAws.ServiceName = "sqs"

success = rest.SetAuthAws(authAws)

success = rest.AddQueryParam("Action","ListQueues")
' List only queues having a name starting with "c".
' Comment out this line to list all queues.
success = rest.AddQueryParam("QueueNamePrefix","c")

Dim responseXml As String
responseXml = rest.FullRequestNoBody("GET","/")
If (rest.LastMethodSuccess <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

' A successful response will have a status code equal to 200.
If (rest.ResponseStatusCode <> 200) Then
    Debug.Print "response status code = " & rest.ResponseStatusCode
    Debug.Print "response status text = " & rest.ResponseStatusText
    Debug.Print "response header: " & rest.ResponseHeader
    Debug.Print "response body: " & responseXml
    Exit Sub
End If

' Examine the successful XML response.
Dim xml As New ChilkatXml
success = xml.LoadXml(responseXml)
Debug.Print xml.GetXml()
Debug.Print "----"

' A successful response looks like this:
' <?xml version="1.0" encoding="utf-8" ?>
' <ListQueuesResponse xmlns="http://queue.amazonaws.com/doc/2012-11-05/">
'     <ListQueuesResult>
'         <QueueUrl>https://sqs.us-west-2.amazonaws.com/123491855557/chilkatTest</QueueUrl>
'         <QueueUrl>https://sqs.us-west-2.amazonaws.com/123496666627/chilkatses</QueueUrl>
'     </ListQueuesResult>
'     <ResponseMetadata>
'         <RequestId>77bce138-fbcc-5e42-9ee3-b15c1f7178c2</RequestId>
'     </ResponseMetadata>
' </ListQueuesResponse>

' Get each queue URL..
success = xml.FindChild2("ListQueuesResult")
Dim i As Long
i = 0
Dim numQueues As Long
numQueues = xml.NumChildren
Do While i < numQueues
    Debug.Print "QueueUrl: " & xml.GetChildContentByIndex(i)
    i = i + 1
Loop

xml.GetRoot2