Visual Basic 6.0

OAuth2 for a GMail using a P12 Service Account Key

See more GMail REST API Examples

Demonstrates how to use GMail with OAuth2 for a service account within a Google Workspace Account where your email domain is custom (e.g., @yourcompany.com).

Note: This example does not work for Personal Google Accounts where the email domain is @gmail.com

Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim http As New ChilkatHttp

' --------------------------------------------------------------------------------
' For a step-by-step guide for setting up your Google Workspace service account,
' see Setup Google Workspace Account for Sending SMTP GMail from a Service Account
' --------------------------------------------------------------------------------
' Begin by loading your Google service account key (.p12)
Dim cert As New ChilkatCert
success = cert.LoadPfxFile("c:/someDirectory/keys/chilkat25-cbd7b42afbd8.p12","notasecret")
If (success <> 1) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

' The ISS is your service account email address ending in gserviceaccount.com.
Dim iss As String
iss = "chilkatsvc@chilkat25.iam.gserviceaccount.com"

' The scope is always the following string:
Dim scope As String
scope = "https://mail.google.com/"

' The sub is your company email address
Dim oauth_sub As String
oauth_sub = "bob@yourcompany.com"

' The access token is valid for this number of seconds.
Dim numSec As Long
numSec = 3600

Dim accessToken As String
accessToken = http.G_SvcOauthAccessToken(iss,scope,oauth_sub,numSec,cert)
If (http.LastMethodSuccess <> 1) Then
    Debug.Print http.LastErrorText
    Exit Sub
Else
    Debug.Print "access token: " & accessToken
End If

' The access token allows us to send unlimited emails while it's valid. Once it expires, we must obtain and use a new one.

' -----------------------------------------------------------------------
Dim mailman As New ChilkatMailMan

' Set the properties for the GMail SMTP server:
mailman.SmtpHost = "smtp.gmail.com"
mailman.SmtpPort = 587
mailman.StartTLS = 1

mailman.SmtpUsername = "bob@yourcompany.com"
mailman.OAuth2AccessToken = accessToken

' Create a new email object
Dim email As New ChilkatEmail

email.Subject = "This is a test"
email.Body = "This is a test"
email.From = "Bob <bob@yourcompany.com>"
success = email.AddTo("Recipient","recipient@example.com")
' To add more recipients, call AddTo, AddCC, or AddBcc once per recipient.

success = mailman.SendEmail(email)
If (success <> 1) Then
    Debug.Print mailman.LastErrorText
    Exit Sub
End If

success = mailman.CloseSmtpConnection()
If (success <> 1) Then
    Debug.Print "Connection to SMTP server not closed cleanly."
End If

Debug.Print "Successfully sent email using Gmail with a service account key."