Visual Basic 6.0

SCP Upload Contents of String to Remote File

See more SCP Examples

Demonstrates how to upload the contents of a string variable using the SCP protocol (Secure Copy Protocol over SSH). The text is uploaded to a file in specific remote directory. If the file did not already exist, it is created. If it already existed, it is overwritten. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim ssh As New ChilkatSsh

' Connect to an SSH server:
Dim hostname As String
Dim port As Long

' Hostname may be an IP address or hostname:
hostname = "www.some-ssh-server.com"
port = 22

success = ssh.Connect(hostname,port)
If (success <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Wait a max of 5 seconds when reading responses..
ssh.IdleTimeoutMs = 5000

' Authenticate using login/password:
success = ssh.AuthenticatePw("myLogin","myPassword")
If (success <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Once the SSH object is connected and authenticated, we use it
' as the underlying transport in our SCP object.
Dim scp As New ChilkatScp

success = scp.UseSsh(ssh)
If (success <> 1) Then
    Debug.Print scp.LastErrorText
    Exit Sub
End If

Dim content As String
content = "This string will be the contents of the remote file."
Dim remotePath As String
remotePath = "uploads/text/testUtf8.txt"

' The utf-8 byte representation of the string will be uploaded.
' See https://www.chilkatsoft.com/p/p_463.asp for a list of valid charsets.
Dim charset As String
charset = "utf-8"

' This uploads to the "uploads/text" directory relative to the HOME
' directory of the SSH user account.  
' Note: The remote target directory must already exist on the SSH server.
success = scp.UploadString(remotePath,content,charset)
If (success <> 1) Then
    Debug.Print scp.LastErrorText
    Exit Sub
End If

remotePath = "uploads/text/testUtf8_withBOM.txt"

' To include the utf-8 preamble (also known as the BOM),
' prefix the charset name with "bom:".  Any charset that can 
' optionally include a BOM can be specified in this way.
charset = "bom:utf-8"

' Uploads to a remote file that contains text in the 
' utf-8 representation, including the BOM at the start of the file.
success = scp.UploadString(remotePath,content,charset)
If (success <> 1) Then
    Debug.Print scp.LastErrorText
    Exit Sub
End If

Debug.Print "SCP upload string success."

' Disconnect
ssh.Disconnect