Visual Basic 6.0

SCP Download Text File to String Variable

See more SCP Examples

Downloads a file using the SCP protocol (Secure Copy Protocol over SSH), from a specific remote directory located on the SSH server directly into a string variable. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim ssh As New ChilkatSsh

' Hostname may be an IP address or hostname:
Dim hostname As String
hostname = "www.some-ssh-server.com"
Dim port As Long
port = 22

' Connect to an SSH server:
success = ssh.Connect(hostname,port)
If (success <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Wait a max of 5 seconds when reading responses..
ssh.IdleTimeoutMs = 5000

' Authenticate using login/password:
success = ssh.AuthenticatePw("myLogin","myPassword")
If (success <> 1) Then
    Debug.Print ssh.LastErrorText
    Exit Sub
End If

' Once the SSH object is connected and authenticated, we use it
' in our SCP object.
Dim scp As New ChilkatScp

success = scp.UseSsh(ssh)
If (success <> 1) Then
    Debug.Print scp.LastErrorText
    Exit Sub
End If

' This downloads a file from the "repositor/xml/" subdirectory (relative to the SSH user account's HOME directory).  
Dim remotePath As String
remotePath = "repository/xml/hamlet.xml"

' The byte representation of the remote text file (i.e. the charset) must be
' indicated to allow the receiving software to correctly interpret the incoming
' bytes as the correct chars.
' See https://www.chilkatsoft.com/p/p_463.asp for a list of valid charset names.
Dim charset As String
charset = "utf-8"

Dim fileContents As String
fileContents = scp.DownloadString(remotePath,charset)
If (scp.LastMethodSuccess <> 1) Then
    Debug.Print scp.LastErrorText
    Exit Sub
End If

Debug.Print "Received file:"
Debug.Print fileContents

Debug.Print "SCP download string success."

' Disconnect
ssh.Disconnect