Visual Basic 6.0

RSA Sign with PKCS8 Encrypted Key

See more RSA Examples

Demonstrates how to load a private key from an encrypted PKCS8 file and create an RSA digital signature (and then verify it). Visual Basic 6.0

Dim success As Long
success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim privKey As New PrivateKey

' Load the private key from an RSA PEM file:
success = privKey.LoadAnyFormatFile("raul_privateKey.key","a0123456789")
If (success = 0) Then
    Debug.Print privKey.LastErrorText
    Exit Sub
End If

Dim rsa As New ChilkatRsa

' Import the private key into the RSA component:
success = rsa.UsePrivateKey(privKey)
If (success = 0) Then
    Debug.Print rsa.LastErrorText
    Exit Sub
End If

' This example will sign a string, and receive the signature
' in a hex-encoded string.  Therefore, set the encoding mode
' to "hex":
rsa.EncodingMode = "hex"

Dim strData As String
strData = "This is the string to be signed."

' Sign the string using the sha256 hash algorithm.
' Other valid choices are sha1, sha384, sha512 and others.
Dim hexSig As String
hexSig = rsa.SignStringENC(strData,"sha256")
If (rsa.LastMethodSuccess = 0) Then
    Debug.Print rsa.LastErrorText
    Exit Sub
End If

Debug.Print hexSig

' Now verify with the public key.
' This example shows how to use the public key from 
' a digital certificate (.cer file)
Dim cert As New ChilkatCert
success = cert.LoadFromFile("raul_publicKey.cer")
If (success = 0) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

Dim pubKey As New PublicKey
success = cert.GetPublicKey(pubKey)

Dim rsa2 As New ChilkatRsa
success = rsa2.UsePublicKey(pubKey)
If (success = 0) Then
    Debug.Print rsa2.LastErrorText
    Exit Sub
End If

' Verify the signature against the original data:
rsa2.EncodingMode = "hex"
success = rsa2.VerifyStringENC(strData,"sha256",hexSig)
If (success = 0) Then
    Debug.Print rsa2.LastErrorText
    Exit Sub
End If

Debug.Print "Signature verified!"

' Verify with incorrect data:
success = rsa2.VerifyStringENC("something else","sha256",hexSig)
If (success <> 1) Then
    Debug.Print "Signature not verified! (which was expected in this case)"
Else
    Debug.Print "Hmmm... that's not right..."
End If