Visual Basic 6.0

Get RSA Key Modulus from .cer or .key

See more Certificates Examples

Demonstrates how to get the RSA key modulus from either the certificate (.cer) or RSA key (.key). OpenSSL commands to do the same would be:

openssl x509 -inform DER -in "test.cer"  -modulus -noout 

or

openssl pkcs8 -inform DER -in​ "test.key"​ -outform PEM -passin pass:"12345​678a​"
   | openssl rsa -inform PEM -modulus -noout 

Visual Basic 6.0

Dim success As Long
success = 0

Dim privKey As New PrivateKey

Dim password As String
password = "12345678a"
success = privKey.LoadPkcs8EncryptedFile("qa_data/certs/test_12345678a.key",password)
If (success = 0) Then
    Debug.Print privKey.LastErrorText
    Exit Sub
End If

Dim xml As New ChilkatXml
success = xml.LoadXml(privKey.GetXml())

' The XML contains the parts of the key in base64.
Debug.Print "Private Key XML:"
Debug.Print xml.GetXml()

' We can get the base64 modulus like this:
Dim modulus As String
modulus = xml.GetChildContent("Modulus")
Debug.Print "base64 modulus = " & modulus

' To convert to hex:
Dim binDat As New ChilkatBinData
success = binDat.AppendEncoded(modulus,"base64")
Dim hexModulus As String
hexModulus = binDat.GetEncoded("hex")
Debug.Print "hex modulus = " & hexModulus

' Now get the modulus from the cert:
Dim cert As New ChilkatCert

success = cert.LoadFromFile("qa_data/certs/test_12345678a.cer")
If (success = 0) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

' The cert contains the public key, which is composed of the
' modulus + exponent (for RSA keys).
Dim pubKey As New PublicKey
success = cert.GetPublicKey(pubKey)

success = xml.LoadXml(pubKey.GetXml())
Debug.Print "Public Key XML:"
Debug.Print xml.GetXml()

' Proceed in the same way as before....
modulus = xml.GetChildContent("Modulus")
Debug.Print "base64 modulus = " & modulus

' To convert to hex:
success = binDat.Clear()
success = binDat.AppendEncoded(modulus,"base64")
hexModulus = binDat.GetEncoded("hex")
Debug.Print "hex modulus = " & hexModulus