(Visual Basic 6.0) Reading Unread POP3 Email

The POP3 protocol does not provide the ability to ask the server which emails are "unread". Furthermore, a pure POP3 server does not even keep this information. Some servers, such as Exchange Server, expose both POP3 and IMAP interfaces. In these cases, information about read/unread status exists on the server, but it is only available via the IMAP protocol. Email clients such as Outlook and Thunderbird keep read/unread information on the client computer. This example demonstrates how UIDLs can be saved to track and read "unread" email.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' The mailman object is used for receiving (POP3) 
' and sending (SMTP) email.
Dim mailman As New ChilkatMailMan

' Set the POP3 server's hostname
mailman.MailHost = "pop.someMailServer.com"

' Set the POP3 login/password.
mailman.PopUsername = "***"
mailman.PopPassword = "***"

' You may keep a list of already-seen UIDLs in a text file:
' If this is the first time you're running this example,
' create an empty text file named "seenUidls.txt"
Dim saSeenUidls As New CkStringArray
Dim success As Long
success = saSeenUidls.LoadFromFile("seenUidls.txt")
If (success <> 1) Then
    Debug.Print "failed to load seenUidls.txt"
    Exit Sub
End If

' Get the complete list of UIDLs on the mail server.
Dim saUidls As CkStringArray
Set saUidls = mailman.GetUidls()
If (mailman.LastMethodSuccess = 0) Then
    Debug.Print mailman.LastErrorText
    Exit Sub
End If

' Create a new string array object (it's an object, not an actual array)
' and add the UIDLs from saUidls that aren't already seen.
Dim saUnseenUidls As New CkStringArray

Dim i As Long
i = 0
Dim n As Long
n = saUidls.Count
Do While i < n
    If (saSeenUidls.Contains(saUidls.GetString(i)) <> 1) Then
        success = saUnseenUidls.Append(saUidls.GetString(i))
    End If

    i = i + 1
Loop

If (saUnseenUidls.Count = 0) Then
    Debug.Print "No unseen emails!"

    Exit Sub
End If

' Download in full the unseen emails:
Dim bundle As ChilkatEmailBundle
Set bundle = mailman.FetchMultiple(saUnseenUidls)
If (mailman.LastMethodSuccess = 0) Then
    Debug.Print mailman.LastErrorText

    Exit Sub
End If

Dim email As ChilkatEmail
i = 0
Do While i < bundle.MessageCount
    Set email = bundle.GetEmail(i)
    Debug.Print email.From
    Debug.Print email.Subject
    Debug.Print "----"

    i = i + 1
Loop

' Save saUidls to "seenUidls.txt"
success = saUidls.SaveToFile("seenUidls.txt")