Visual Basic 6.0

PC/SC Get Card UID

See more SCard Examples

Sends the APDU command to get a card's UID. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim scard As New ChilkatSCard

' First establish a context to the PC/SC Resource Manager
success = scard.EstablishContext("user")
If (success = 0) Then
    Debug.Print scard.LastErrorText
    Exit Sub
End If

' Use your own smart card reader name here.
success = scard.Connect("ACS ACR122 0","shared","no_preference")
If (success = 0) Then
    Debug.Print scard.LastErrorText
    Exit Sub
End If

Debug.Print "Connected reader: " & scard.ConnectedReader
Debug.Print "Active protocol: " & scard.ActiveProtocol
Debug.Print "ATR: " & scard.CardAtr
Debug.Print "Reader Status: " & scard.ReaderStatus

'  Send the APDU command 0xFF, 0xCA, 0x00, 0x00, 0x00
Dim bdRecv As New ChilkatBinData
success = scard.TransmitHex(scard.ActiveProtocol,"FFCA000000",bdRecv,32)
If (success = 1) Then

    Debug.Print "Received: " & bdRecv.GetEncoded("hex")

    ' The UID is the returned data without the final 2 bytes.
    Dim numBytes As Long
    numBytes = bdRecv.NumBytes
    If (numBytes > 2) Then
        Debug.Print "UID: " & bdRecv.GetEncodedChunk(0,numBytes - 2,"hex")
    End If

Else
    Debug.Print scard.LastErrorText
End If

' Disconnect from this reader.
success = scard.Disconnect("leave")
If (success = 0) Then
    Debug.Print scard.LastErrorText
End If

' Applications should always release the context when finished.
success = scard.ReleaseContext()
If (success = 0) Then
    Debug.Print scard.LastErrorText
End If