Visual Basic 6.0

Microsoft Teams OAuth2 Client Credentials Authentication

See more Microsoft Teams Examples

Demonstrates how to authenticate with OAuth 2.0 using the client credentials grant type. Visual Basic 6.0

Dim success As Long
success = 0

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim http As New ChilkatHttp

' Provide the information needed for Chilkat to automatically fetch the OAuth2.0 
' access token as needed.
' This is the new "Integrated OAuth2 Client Credentials" feature introduced in Chilkat v9.5.0.96.  
Dim jsonOAuthCC As New ChilkatJsonObject

' --------------------------------------------------------------------------------------------------------
' You'll need to have registered an app in Azure beforehand.
' 
' Note: Creating a Team requires the following Application permissions:
' Team.Create, Teamwork.Migrate.All, Group.ReadWrite.All**, Directory.ReadWrite.All**
' 
' See How to Create an Azure App Registration for OAuth 2.0 Client Credentials
' --------------------------------------------------------------------------------------------------------

' Use the values from your App Registration in Azure.
success = jsonOAuthCC.UpdateString("client_id","e1cd2318-xxxx-4916-bfd6-xxxxxxxxxxxx")
success = jsonOAuthCC.UpdateString("client_secret","K.d8Q~RoJxxxxvCj_u_xxxxxxxxxxxxxxxxxxxxx")

' You'll always use this scope for client credentials, because the allowed actions
' are determined by the App Permissions defined when you registered the app in Azure.
success = jsonOAuthCC.UpdateString("scope","https://graph.microsoft.com/.default")

' The token endpoint includes your tenant ID.  Use your tenant ID (not the tenant ID shown here).
success = jsonOAuthCC.UpdateString("token_endpoint","https://login.microsoftonline.com/112d7ed6-71bf-4eba-a866-738364321bfc/oauth2/v2.0/token")

' Provide the OAuth2 information. Chilkat will use this information to automatically fetch the OAuth2 access token as needed,
http.AuthToken = jsonOAuthCC.Emit()

' ------------------------------------------------------------------------------
' To create a Microsoft Team, we want to send an HTTP request like the following:
' 
' Note: The following is the minimal JSON for a request using Applicaton permissions (i.e. the access token retrieved using the client credentials grant).
' 
' POST https://graph.microsoft.com/v1.0/teams
' Content-Type: application/json
' 
' {
'    "template@odata.bind":"https://graph.microsoft.com/v1.0/teamsTemplates('standard')",
'    "displayName":"My Sample Team",
'    "description":"My Sample Team�s Description",
'    "members":[
'       {
'          "@odata.type":"#microsoft.graph.aadUserConversationMember",
'          "roles":[
'             "owner"
'          ],
'          "user@odata.bind":"https://graph.microsoft.com/v1.0/users('0040b377-61d8-43db-94f5-81374122dc7e')"
'       }
'    ]
' }

Dim json As New ChilkatJsonObject
success = json.UpdateString("""template@odata.bind""","https://graph.microsoft.com/v1.0/teamsTemplates('standard')")
success = json.UpdateString("displayName","My Sample Team")
success = json.UpdateString("description","My Sample Team�s Description")
success = json.UpdateString("members[0].""@odata.type""","#microsoft.graph.aadUserConversationMember")
success = json.UpdateString("members[0].roles[0]","owner")
success = json.UpdateString("members[0].""user@odata.bind""","https://graph.microsoft.com/v1.0/users('4ee732c3-322e-4a6b-b729-2fd1eb5c6004')")

json.EmitCompact = 0
Debug.Print json.Emit()

http.SetRequestHeader "Content-type","application/json"

Dim resp As New ChilkatHttpResponse
success = http.HttpJson("POST","https://graph.microsoft.com/v1.0/teams",json,"application/json",resp)
If (success = 0) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

' A successful response is indicated by a 202 response status code and an empty response body.
Debug.Print "Response Status Code: " & resp.StatusCode
Debug.Print "Response Body:"
Debug.Print resp.BodyStr

If (resp.StatusCode >= 400) Then
    Debug.Print "Response Header:"
    Debug.Print resp.Header
    Debug.Print "Failed."
End If