Visual Basic 6.0

Verify a JWT Created by the Amazon Cognito Service

See more JSON Web Token (JWT) Examples

Demonstrates how to verify a JWT created by the Amazon Cognito Service. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' The public keys for this example are at https://cognito-idp.us-east-2.amazonaws.com/us-east-2_******/.well-known/jwks.json
' Let's get them:

Dim http As New ChilkatHttp
Dim sbJsonKeys As New ChilkatStringBuilder
success = http.QuickGetSb("https://cognito-idp.us-east-2.amazonaws.com/us-east-2_******/.well-known/jwks.json",sbJsonKeys)
If (success = 0) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

Dim jsonKeys As New ChilkatJsonObject
success = jsonKeys.LoadSb(sbJsonKeys)
jsonKeys.EmitCompact = 0
Debug.Print jsonKeys.Emit()

' Here are the keys:

' {
'   "keys": [
'     {
'       "alg": "RS256",
'       "e": "AQAB",
'       "kid": "1A/L5Fsb2EsEwxy5E0cmCMS1BnMe6Jl6NXiMig4iNwU=",
'       "kty": "RSA",
'       "n": "y0w7BJrIJYi ... jKG27z2P3OKw",
'       "use": "sig"
'     },
'     {
'       "alg": "RS256",
'       "e": "AQAB",
'       "kid": "mos6VTJnvDwurY3ghJg6IAPUq+dMwl6CL/iThzJOkzg=",
'       "kty": "RSA",
'       "n": "qbIEH-7tg6yrT ... 3Fj94ooTd0w",
'       "use": "sig"
'     }
'   ]
' }

' Try the 1st key.
Dim jsonKey1 As New ChilkatJsonObject
success = jsonKeys.ObjectOf2("keys[0]",jsonKey1)

Dim pubKey1 As New PublicKey
success = pubKey1.LoadFromString(jsonKey1.Emit())
If (success = 0) Then
    Debug.Print pubKey1.LastErrorText
    Exit Sub
End If

Debug.Print "Success"

Dim jwt As New ChilkatJwt

' I did not include the an actual AWS Cognito token here because our test sample used customer-provided data..
Dim token As String
token = "eyJ..asXg"

' First verify the signature.
Dim sigVerified As Long
sigVerified = jwt.VerifyJwtPk(token,pubKey1)
Debug.Print "verified: " & sigVerified

' Let's see if the time constraints, if any, are valid.
' The above JWT was created on the afternoon of 16-May-2016, with an expiration of 1 hour.
' If the current system time is before the "nbf" time, or after the "exp" time,
' then IsTimeValid will return false/0.
' Also, we'll allow a leeway of 60 seconds to account for any clock skew.
' Note: If the token has no "nbf" or "exp" claim fields, then IsTimeValid is always true.
Dim leeway As Long
leeway = 60
Dim bTimeValid As Long
bTimeValid = jwt.IsTimeValid(token,leeway)
Debug.Print "time constraints valid: " & bTimeValid

' Now let's recover the original claims JSON (the payload).
Dim payload As String
payload = jwt.GetPayload(token)
' The payload will likely be in compact form:
Debug.Print payload

' We can format for human viewing by loading it into Chilkat's JSON object
' and emit.
Dim json As New ChilkatJsonObject
success = json.Load(payload)
json.EmitCompact = 0
Debug.Print json.Emit()

' We can recover the original JOSE header in the same way:
Dim joseHeader As String
joseHeader = jwt.GetHeader(token)
' The payload will likely be in compact form:
Debug.Print joseHeader

' We can format for human viewing by loading it into Chilkat's JSON object
' and emit.
success = json.Load(joseHeader)
json.EmitCompact = 0
Debug.Print json.Emit()