Visual Basic 6.0

JSON: Nested Array

See more JSON Examples

Here we have a JSON object that contains nested arrays. This example demonstrates how to access the contents of the nested arrays.

{
 "numbers" : [ 
    ["even", 2, 4, 6, 8], 
    ["prime", 2, 3, 5, 7, 11, 13] 
  ] }

Visual Basic 6.0

Dim success As Long
success = 0

Dim json As New ChilkatJsonObject

' This is the above JSON with whitespace chars removed (SPACE, TAB, CR, and LF chars).
' The presence of whitespace chars for pretty-printing makes no difference to the Load
' method. 
Dim jsonStr As String
jsonStr = "{ ""numbers"" : [ [""even"", 2, 4, 6, 8], [""prime"", 2, 3, 5, 7, 11, 13] ] }"

success = json.Load(jsonStr)
If (success <> 1) Then
    Debug.Print json.LastErrorText
    Exit Sub
End If

' Get the value of the "numbers" object, which is an array that contains JSON arrays.
Dim outerArray As ChilkatJsonArray
Set outerArray = json.ArrayOf("numbers")
If (json.LastMethodSuccess = 0) Then
    Debug.Print "numbers array not found."
    Exit Sub
End If

Dim numArrays As Long
numArrays = outerArray.Size
Dim i As Long

For i = 0 To numArrays - 1

    Dim innerArray As ChilkatJsonArray
    Set innerArray = outerArray.ArrayAt(i)

    ' The first item in the innerArray is a string
    Debug.Print innerArray.StringAt(0) & ":"

    Dim numInnerItems As Long
    numInnerItems = innerArray.Size
    Dim j As Long
    For j = 1 To numInnerItems - 1

        Debug.Print "  " & innerArray.IntAt(j)

    Next

Next