Visual Basic 6.0

Get Access Token for Google Tasks using Service Account JSON Key

See more Google Tasks Examples

Demonstrates how to get an access token for the Google Tasks API using a Service Account JSON key. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' First load the JSON key into a string.
Dim fac As New CkFileAccess
Dim jsonKey As String
jsonKey = fac.ReadEntireTextFile("qa_data/googleSvcAccountKeys/ChilkatCloud-48f7737c7505.json","utf-8")
If (fac.LastMethodSuccess <> 1) Then
    Debug.Print fac.LastErrorText
    Exit Sub
End If

' A JSON private key should look like this:

' {
'   "type": "service_account",
'   "project_id": "chilkatcloud",
'   "private_key_id": "48f7737c7505bb88eee6a20d09993e10605d466e",
'   "private_key": "-----BEGIN PRIVATE KEY----- ... -----END PRIVATE KEY-----\n",
'   "client_email": "pip-564@chilkatcloud.iam.gserviceaccount.com",
'   "client_id": "109982228323456925225",
'   "auth_uri": "https://accounts.google.com/o/oauth2/auth",
'   "token_uri": "https://oauth2.googleapis.com/token",
'   "auth_provider_x509_cert_url": "https://www.googleapis.com/oauth2/v1/certs",
'   "client_x509_cert_url": "https://www.googleapis.com/robot/v1/metadata/x509/pip-564%40chilkatcloud.iam.gserviceaccount.com"
' }

Dim gAuth As New ChilkatAuthGoogle
gAuth.JsonKey = jsonKey

' Choose the scope for read/write access.
gAuth.Scope = "https://www.googleapis.com/auth/tasks"

' Request an access token that is valid for this many seconds.
gAuth.ExpireNumSeconds = 3600

gAuth.SubEmailAddress = ""

' Connect to www.googleapis.com using TLS
Dim tlsSock As New ChilkatSocket
success = tlsSock.Connect("www.googleapis.com",443,1,5000)
If (success <> 1) Then
    Debug.Print tlsSock.LastErrorText
    Exit Sub
End If

' Send the request to obtain the access token.
success = gAuth.ObtainAccessToken(tlsSock)
If (success <> 1) Then
    Debug.Print gAuth.LastErrorText
    Exit Sub
End If

' Examine the access token:
Debug.Print "Access Token: " & gAuth.AccessToken

' Save our access token to a file.
success = fac.WriteEntireTextFile("qa_data/tokens/googleTasks.txt",gAuth.AccessToken,"utf-8",0)