Visual Basic 6.0

Get a Google Drive Access Token using a JSON Private Key

See more Google Drive Examples

Demonstrates how to get a Google Drive API access token using a JSON service account private key. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' First load the JSON key into a string.
Dim fac As New CkFileAccess
Dim jsonKey As String
jsonKey = fac.ReadEntireTextFile("qa_data/googleApi/chilkatcloud-b8826e030499.json","utf-8")
If (fac.LastMethodSuccess <> 1) Then
    Debug.Print fac.LastErrorText
    Exit Sub
End If

Dim gAuth As New ChilkatAuthGoogle
gAuth.JsonKey = jsonKey

' Choose a scope.
gAuth.Scope = "https://www.googleapis.com/auth/drive"

' Request an access token that is valid for this many seconds.
gAuth.ExpireNumSeconds = 3600

' If the application is requesting delegated access:
' The email address of the user for which the application is requesting delegated access,
' then set the email address here. (Otherwise leave it empty.)
gAuth.SubEmailAddress = ""

' Connect to www.googleapis.com using TLS (TLS 1.2 is the default.)
' The Chilkat socket object is used so that the connection can be established
' through proxies or an SSH tunnel if desired.
Dim tlsSock As New ChilkatSocket
success = tlsSock.Connect("www.googleapis.com",443,1,5000)
If (success <> 1) Then
    Debug.Print tlsSock.LastErrorText
    Exit Sub
End If

' Send the request to obtain the access token.
success = gAuth.ObtainAccessToken(tlsSock)
If (success <> 1) Then
    Debug.Print gAuth.LastErrorText
    Exit Sub
End If

' Examine the access token:
Debug.Print "Access Token: " & gAuth.AccessToken