Visual Basic 6.0

Refresh GMail SMTP OAuth2 Access Token

See more OAuth2 Examples

Demonstrates how to refresh an access token for sending email via GMail (SMTP). Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' See Get GMail SMTP Access Token 
' for sample code showing how to obtain a GMail SMTP access token for desktop apps.

' It is assumed we previously obtained an OAuth2 access token for GMail (one with a scope for sending email).

Dim jsonToken As New ChilkatJsonObject
success = jsonToken.LoadFile("qa_data/tokens/_gmailSmtp.json")
If (success <> 1) Then
    Debug.Print "Failed to load _gmailSmtp.json"
    Exit Sub
End If

' The access token JSON looks something like this:

' 	{ 
' 	 "access_token": "abac.Ci-ZabcdF37-NUrmSzxbHxTsMbtlN-uPfabcdAQN_2ekzj0s5ofCzRabcdTDMGaa2Q",
' 	 "token_type": "Bearer",
' 	 "expires_in": 3600,
' 	 "refresh_token": "1/lEe5abcdNJ77eOSDBabcdkQGVmDalkwabcdR2Hatbo"
' 	}
' 

Dim oauth2 As New ChilkatOAuth2

oauth2.TokenEndpoint = "https://www.googleapis.com/oauth2/v4/token"

' Replace these with actual values.
oauth2.ClientId = "GOOGLE-CLIENT-ID"
oauth2.ClientSecret = "GOOGLE-CLIENT-SECRET"

' Get the "refresh_token"
oauth2.RefreshToken = jsonToken.StringOf("refresh_token")

' Send the HTTP POST to refresh the access token..
success = oauth2.RefreshAccessToken()
If (success <> 1) Then
    Debug.Print oauth2.LastErrorText
    Exit Sub
End If

' The response contains a new access token, but we must keep
' our existing refresh token for when we need to refresh again in the future.
success = jsonToken.UpdateString("access_token",oauth2.AccessToken)

' Save the new JSON access token response to a file.
Dim sbJson As New ChilkatStringBuilder
jsonToken.EmitCompact = 0
success = jsonToken.EmitSb(sbJson)
success = sbJson.WriteFile("qa_data/tokens/_gmailSmtp.json","utf-8",0)

Debug.Print "OAuth2 authorization granted!"
Debug.Print "New Access Token = " & oauth2.AccessToken