Visual Basic 6.0

Upload to Tumbleweed SecureTransport FTPS Server

See more FTP Examples

Demonstrates how to connect, authenticate, and upload file to a Tumbleweed Secure Transport SSL FTP Server. Instead of providing a login name and password, you pass the string "site-auth" for the username, and an empty string for the password. You must also provide a client-side digital certificate -- as the certificate's credentials and validity are used to authenticate. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim ftp As New ChilkatFtp2

' This code has been tested with the Tumbleweed server
' at sft.wellsfargo.com
ftp.Hostname = "sft.wellsfargo.com"

' Use these exact strings for the username and password:
ftp.Username = "site-auth"
ftp.Password = ""

' Establish an AUTH SSL secure channel after connecting.
' Your client-side certificate is used for authentication when
' the SSL channel is established.
ftp.AuthSsl = 1

' The Ssl property is for establishing an implicit SSL connection
' on port 990.  Do not set it.
ftp.Ssl = 0

' Load a certificate from a .pfx
' A PFX may contain several certs, including the certificates
' in a chain of authority.
Dim certStore As New ChilkatCertStore
Dim password As String
password = "***"
' Load the certs from a PFX into an in-memory certificate store:
success = certStore.LoadPfxFile("my.pfx",password)
If (success <> 1) Then
    Debug.Print certStore.LastErrorText
    Exit Sub
End If

' Find the desired certificate.
Dim jsonCN As New ChilkatJsonObject
success = jsonCN.UpdateString("CN","cert common name")

Dim cert As New ChilkatCert
success = certStore.FindCert(jsonCN,cert)
If (success = 0) Then
    Debug.Print "Certificate not found!"
    Exit Sub
End If

' Tell the Chilkat FTP2 component to use the client-side
' cert for the SSL connection:
success = ftp.SetSslClientCert(cert)

' Connect and authenticate with the FTP server.
success = ftp.Connect()
If (success <> 1) Then
    Debug.Print ftp.LastErrorText
    Exit Sub
Else
    ' LastErrorText contains information even when
    ' successful. This allows you to visually verify
    ' that the secure connection actually occurred.
    Debug.Print ftp.LastErrorText
End If

Debug.Print "Secure FTP Channel Established!"

' Change to the remote directory where the file will be
' uploaded.  If your file is to be uploaded to the FTP user 
' account's home directory, this is not necessary.
success = ftp.ChangeRemoteDir("someSubDir")
If (success <> 1) Then
    Debug.Print ftp.LastErrorText
    Exit Sub
End If

' You may include an absolute or relative path with the 
' local filename.  If no path is included, the file should 
' be present in the current working directory of the calling
' process.
Dim localFilename As String
localFilename = "someFile.dat"
Dim remoteFilename As String
remoteFilename = "someFile.dat"

' Upload the file.
success = ftp.PutFile(localFilename,remoteFilename)
If (success <> 1) Then
    Debug.Print ftp.LastErrorText
    Exit Sub
End If

success = ftp.Disconnect()