Visual Basic 6.0

Secure FTP with Client Certificate

See more FTP Examples

Chilkat FTP2 provides the ability to use a client certificate with secure FTP (implicit or explicit SSL/TLS). This example demonstrates how to load a certificate from a .pfx and use it as the client-side SSL cert. Note: Client-side certificates are only needed in situations where the server demands one. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim ftp As New ChilkatFtp2

ftp.Hostname = "ftp.example.com"
ftp.Port = 21
ftp.Username = "test"
ftp.Password = "test"

' This example will use explict TLS/SSL.
' Establish an explicit secure channel after connection
' on the standard FTP port 21.
ftp.AuthTls = 1

' The Ssl property is for establishing an implicit SSL connection
' on port 990.  Because this example uses explicit SSL, it 
' should remain 0.
ftp.Ssl = 0

' Load a certificate from a .pfx
' A PFX may contain several certs, including the certificates
' in a chain of authority.
Dim certStore As New ChilkatCertStore
Dim password As String
password = "***"
' Load the certs from a PFX into an in-memory certificate store:
success = certStore.LoadPfxFile("chilkat.pfx",password)
If (success <> 1) Then
    Debug.Print certStore.LastErrorText
    Exit Sub
End If

' Find the desired certificate.
Dim jsonCN As New ChilkatJsonObject
success = jsonCN.UpdateString("CN","cert common name")

Dim cert As New ChilkatCert
success = certStore.FindCert(jsonCN,cert)
If (success = 0) Then
    Debug.Print "Certificate not found!"
    Exit Sub
End If

' Use this certificate for our secure (SSL/TLS) connection:
success = ftp.SetSslClientCert(cert)

' Connect and login to the FTP server.  The connection is 
' made secure because of the AuthTls setting.
success = ftp.Connect()
If (success <> 1) Then
    Debug.Print ftp.LastErrorText
    Exit Sub
Else
    ' LastErrorText contains information even when
    ' successful. This allows you to visually verify
    ' that the secure connection actually occurred.
    Debug.Print ftp.LastErrorText
End If

Debug.Print "Secure FTP Channel Established!"

' Do whatever you're doing to do ...
' upload files, download files, etc...

' .....
' .....

success = ftp.Disconnect()