Visual Basic 6.0

Using WS_FTP Self-signed Certificate file (.crt) and Private Key File. (.key)

See more FTP Examples

Demonstrates how to use a self-signed certificate created by WS_FTP with Chilkat FTP2.

Note: It is usually not necessary for the FTP client to use a client-side certificate. Most FTP servers using SSL and TLS connections (explicit or implicit) do not require client-side certs. In addition, some high-security FTP servers require "real" certificates -- meaning certificates issued by a real certificate authority with a chain of authentication that leads to a trusted root certificate. The certificates created by WS_FTP are self-signed and untrusted.

Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Important:  Before running this program, convert your
' .crt and .key files to a .p12 using OpenSSL:
' The command is this:
' openssl pkcs12 -export -in test.crt -inkey test.key -out test.p12
' 

Dim ftp As New ChilkatFtp2

ftp.Hostname = "ftp.example.com"
ftp.Port = 21
ftp.Username = "testLogin"
ftp.Password = "testPassword"

' This example will use explict TLS/SSL.
' Establish an explicit secure channel after connection
' on the standard FTP port 21.
ftp.AuthTls = 1

' The Ssl property is for establishing an implicit SSL connection
' on port 990.  Because this example uses explicit SSL, it 
' should remain 0.
ftp.Ssl = 0

' Create an instance of a certificate store object, load a .p12 file,
' locate the certificate we need, and use it for signing.
' (a P12/PFX file may contain more than one certificate.)
Dim certStore As New ChilkatCertStore
' The 1st argument is the filename, the 2nd arg is the 
' .p12 file's password.  (OpenSSL will prompty you to set a password
' when converting the .crt and .key into a .p12).
success = certStore.LoadPfxFile("test.p12","secret")
If (success <> 1) Then
    Debug.Print certStore.LastErrorText
    Exit Sub
End If

Dim jsonCN As New ChilkatJsonObject
success = jsonCN.UpdateString("CN","cert common name")

Dim cert As New ChilkatCert
success = certStore.FindCert(jsonCN,cert)
If (success = 0) Then
    Debug.Print certStore.LastErrorText
    Exit Sub
End If

success = ftp.SetSslClientCert(cert)

' Connect and login to the FTP server.
success = ftp.Connect()
If (success <> 1) Then
    Debug.Print ftp.LastErrorText
    Exit Sub
Else
    ' LastErrorText contains information even when
    ' successful. This allows you to visually verify
    ' that the secure connection actually occurred.
    Debug.Print ftp.LastErrorText
End If

Debug.Print "Secure FTP Channel Established!"
Debug.Print ftp.LastErrorText

' Do whatever you're doing to do ...
' upload files, download files, etc...

' ...
' ...

success = ftp.Disconnect()