Visual Basic 6.0
Visual Basic 6.0
Belgium eHealth Platform - checkAccessControl
See more Belgian eHealth Platform Examples
Demonstrates the checkAccessControl operation of PlatformIntegrationConsumerTest, which requires an X.509 certificate and signature. This tests the validity of your certificate and signature.Chilkat Visual Basic 6.0 Downloads
Dim success As Long
success = 0
' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.
' Provide a certificate + private key.
' Note: If your certificate + private key is located on a hardware token or smartcard, you can call a different function to load from smartcard..
Dim cert As New ChilkatCert
success = cert.LoadPfxFile("SSIN=12345678.acc.p12","p12_password")
If (success = 0) Then
Debug.Print cert.LastErrorText
Exit Sub
End If
' Create the XML to be signed...
Dim xmlToSign As New ChilkatXml
xmlToSign.Tag = "soapenv:Envelope"
success = xmlToSign.AddAttribute("xmlns:soapenv","http://schemas.xmlsoap.org/soap/envelope/")
success = xmlToSign.AddAttribute("xmlns:urn","urn:be:fgov:ehealth:platformintegrationconsumertest:v1")
success = xmlToSign.AddAttribute("xmlns:urn1","urn:be:fgov:ehealth:platformintegrationconsumertest:types:v1")
success = xmlToSign.UpdateAttrAt("soapenv:Header|wsse:Security",1,"xmlns:wsse","http://docs.oasis-open.org/wss/2004/01/oasis-200401-wss-wssecurity-secext-1.0.xsd")
success = xmlToSign.UpdateAttrAt("soapenv:Header|wsse:Security",1,"xmlns:wsu","http://docs.oasis-open.org/wss/2004/01/oasis-200401-wss-wssecurity-utility-1.0.xsd")
success = xmlToSign.UpdateAttrAt("soapenv:Header|wsse:Security|wsse:BinarySecurityToken",1,"EncodingType","http://docs.oasis-open.org/wss/2004/01/oasis-200401-wss-soap-message-security-1.0#Base64Binary")
success = xmlToSign.UpdateAttrAt("soapenv:Header|wsse:Security|wsse:BinarySecurityToken",1,"ValueType","http://docs.oasis-open.org/wss/2004/01/oasis-200401-wss-x509-token-profile-1.0#X509v3")
success = xmlToSign.UpdateAttrAt("soapenv:Header|wsse:Security|wsse:BinarySecurityToken",1,"wsu:Id","X509-FC77E2C72083DA8E0F16711753508182856")
' ---------------------------------------------------------------------------------------------------------------
' A note about the Id's, such as X509-FC77E2C72083DA8E0F16711753508182856, TS-FC77E2C72083DA8E0F16711753508042855, etc.
' These Id's simply need to be unique within the XML document. You don't need to generate new Id's every time.
' You can use the same Id's in each XML document that is submitted. The purpose of each Id is to
' match the XMLDsig Reference to the element in XML being referenced.
' In other words, you could use the Id's "mickey_mouse", "donald_duck", and "goofy", and it would work perfectly OK,
' as long as no other XML elements also use the Id's "mickey_mouse", "donald_duck", or "goofy"
' ---------------------------------------------------------------------------------------------------------------
Dim bdCert As New ChilkatBinData
success = cert.ExportCertDerBd(bdCert)
xmlToSign.UpdateChildContent "soapenv:Header|wsse:Security|wsse:BinarySecurityToken",bdCert.GetEncoded("base64")
success = xmlToSign.UpdateAttrAt("soapenv:Header|wsse:Security|wsu:Timestamp",1,"wsu:Id","TS-FC77E2C72083DA8E0F16711753508042855")
Dim dt As New CkDateTime
success = dt.SetFromCurrentSystemTime()
xmlToSign.UpdateChildContent "soapenv:Header|wsse:Security|wsu:Timestamp|wsu:Created",dt.GetAsTimestamp(0)
success = dt.AddSeconds(3600)
xmlToSign.UpdateChildContent "soapenv:Header|wsse:Security|wsu:Timestamp|wsu:Expires",dt.GetAsTimestamp(0)
success = dt.AddSeconds(-3600)
success = xmlToSign.UpdateAttrAt("soapenv:Body",1,"wsu:Id","id-FC77E2C72083DA8E0F16711753508182859")
success = xmlToSign.UpdateAttrAt("soapenv:Body",1,"xmlns:wsu","http://docs.oasis-open.org/wss/2004/01/oasis-200401-wss-wssecurity-utility-1.0.xsd")
xmlToSign.UpdateChildContent "soapenv:Body|urn:CheckAccessControlRequest|urn1:Message","Hello World"
' Create a timestamp with the current date/time in the following format: 2014-12-30T15:29:03.157+01:00
xmlToSign.UpdateChildContent "soapenv:Body|urn:CheckAccessControlRequest|urn1:Timestamp",dt.GetAsTimestamp(1)
Dim gen As New ChilkatXmlDSigGen
gen.SigLocation = "soapenv:Envelope|soapenv:Header|wsse:Security|wsse:BinarySecurityToken"
gen.SigLocationMod = 1
gen.SigId = "SIG-FC77E2C72083DA8E0F16711753508252860"
gen.SigNamespacePrefix = "ds"
gen.SigNamespaceUri = "http://www.w3.org/2000/09/xmldsig#"
gen.SignedInfoPrefixList = "soapenv urn urn1"
gen.IncNamespacePrefix = "ec"
gen.IncNamespaceUri = "http://www.w3.org/2001/10/xml-exc-c14n#"
gen.SignedInfoCanonAlg = "EXCL_C14N"
gen.SignedInfoDigestMethod = "sha256"
' Set the KeyInfoId before adding references..
gen.KeyInfoId = "KI-FC77E2C72083DA8E0F16711753508182857"
' -------- Reference 1 --------
success = gen.AddSameDocRef("TS-FC77E2C72083DA8E0F16711753508042855","sha256","EXCL_C14N","wsse soapenv urn urn1","")
' -------- Reference 2 --------
success = gen.AddSameDocRef("id-FC77E2C72083DA8E0F16711753508182859","sha256","EXCL_C14N","urn urn1","")
' -------- Reference 3 --------
success = gen.AddSameDocRef("X509-FC77E2C72083DA8E0F16711753508182856","sha256","EXCL_C14N","_EMPTY_","")
success = gen.SetX509Cert(cert,1)
gen.KeyInfoType = "Custom"
' Create the custom KeyInfo XML..
Dim xmlCustomKeyInfo As New ChilkatXml
xmlCustomKeyInfo.Tag = "wsse:SecurityTokenReference"
success = xmlCustomKeyInfo.AddAttribute("wsu:Id","STR-FC77E2C72083DA8E0F16711753508182858")
success = xmlCustomKeyInfo.UpdateAttrAt("wsse:Reference",1,"URI","#X509-FC77E2C72083DA8E0F16711753508182856")
success = xmlCustomKeyInfo.UpdateAttrAt("wsse:Reference",1,"ValueType","http://docs.oasis-open.org/wss/2004/01/oasis-200401-wss-x509-token-profile-1.0#X509v3")
xmlCustomKeyInfo.EmitXmlDecl = 0
gen.CustomKeyInfoXml = xmlCustomKeyInfo.GetXml()
' Load XML to be signed...
Dim sbXml As New ChilkatStringBuilder
success = xmlToSign.GetXmlSb(sbXml)
gen.Behaviors = "IndentedSignature"
' Sign the XML...
success = gen.CreateXmlDSigSb(sbXml)
If (success = 0) Then
Debug.Print gen.LastErrorText
Exit Sub
End If
' -----------------------------------------------
' Send the signed XML...
Dim http As New ChilkatHttp
success = http.SetSslClientCert(cert)
If (success = 0) Then
Debug.Print http.LastErrorText
Exit Sub
End If
http.SetRequestHeader "Content-Type","text/xml"
' Change to services.ehealth.fgov.be for the production environment.
Dim resp As New ChilkatHttpResponse
success = http.HttpSb("POST","https://services-acpt.ehealth.fgov.be/PlatformIntegrationConsumerTest/v1",sbXml,"utf-8","application/xml",resp)
If (success = 0) Then
Debug.Print http.LastErrorText
Exit Sub
End If
Debug.Print resp.BodyStr
Debug.Print "response status code = " & resp.StatusCode
' A successful response is a 200 status code, with this sample response:
' <soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/">
' <soapenv:Header xmlns:v1="urn:be:fgov:ehealth:platformintegrationconsumertest:v1" xmlns:v11="urn:be:fgov:ehealth:platformintegrationconsumertest:types:v1"/>
' <soapenv:Body xmlns:ic="urn:be:fgov:ehealth:platformintegrationconsumertest:v1" xmlns:type="urn:be:fgov:ehealth:platformintegrationconsumertest:types:v1">
' <ic:CheckAccessControlResponse>
' <type:Message>Hello World</type:Message>
' <type:Timestamp>2023-09-28T22:17:26.643+02:00</type:Timestamp>
' <type:AuthenticatedConsumer>CN="SSIN=aaaaaa", OU=eHealth-platform Belgium, OU=bbbb, OU="SSIN=aaaaaaa", O=Federal Government, C=BE</type:AuthenticatedConsumer>
' </ic:CheckAccessControlResponse>
' </soapenv:Body>
' </soapenv:Envelope>