Visual Basic 6.0

Docusign JSON Web Token (JWT) Grant

See more DocuSign Examples

Demonstrates how to obtain an access token using the JSON Web Token (JWT) Grant. This is good for service integrations where authorization and authentication is automated and cannot have interactive Docusign account owner interaction. Consent for the access is obtained beforehand in various ways. See Obtaining Consent. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' 1. Assume we have already requested and obtained application consent.
'    (See Request Docusign Application Consent
' 
' 2. Create a JWT Token.
' 
Dim privKey As New PrivateKey

' Load an RSA private key from a PEM file.
success = privKey.LoadPemFile("qa_data/pem/docusign_private_rsa_key.pem")
If (success = 0) Then
    Debug.Print privKey.LastErrorText
    Exit Sub
End If

Dim jwt As New ChilkatJwt

' Build the JOSE header
Dim jose As New ChilkatJsonObject
' Use RS256.  Pass the string "RS384" or "RS512" to use RSA with SHA-384 or SHA-512.
success = jose.AppendString("alg","RS256")
success = jose.AppendString("typ","JWT")

' Now build the JWT claims (also known as the payload)
Dim claims As New ChilkatJsonObject

' Replace these with actual values.
' The client ID is also known as the "integration key" in Docusign.
success = claims.AppendString("iss","MY_DOCUSIGN_CLIENT_ID")
' In your DocuSign Admin/Account/UserProfile, this is the API Username, such as 14612117-2530-4982-8c49-ba8766303272
success = claims.AppendString("sub","DOCUSIGN_USER_ID")
success = claims.AppendString("aud","account-d.docusign.com")
success = claims.AppendString("scope","signature")

' Set the timestamp of when the JWT was created to now.
Dim curDateTime As Long
curDateTime = jwt.GenNumericDate(0)
success = claims.AddIntAt(-1,"iat",curDateTime)

' Set the "not process before" timestamp to now.
success = claims.AddIntAt(-1,"nbf",curDateTime)

' Set the timestamp defining an expiration time (end time) for the token
' to be now + 1 hour (3600 seconds)
success = claims.AddIntAt(-1,"exp",curDateTime + 3600)

' Produce the smallest possible JWT:
jwt.AutoCompact = 1

' Create the JWT token.  This is where the RSA signature is created.
Dim token As String
token = jwt.CreateJwtPk(jose.Emit(),claims.Emit(),privKey)

Debug.Print token

' Do the following CURL statement to get the response JSON which contains the access token.
' curl --data "grant_type=urn:ietf:params:oauth:grant-type:jwt-bearer&assertion=YOUR_JSON_WEB_TOKEN" 
'      --request POST https://account-d.docusign.com/oauth/token
Dim http As New ChilkatHttp

Dim req As New ChilkatHttpRequest
req.AddParam "grant_type","urn:ietf:params:oauth:grant-type:jwt-bearer"
req.AddParam "assertion",token

req.HttpVerb = "POST"
req.ContentType = "application/x-www-form-urlencoded"

Dim resp As New ChilkatHttpResponse
success = http.HttpReq("https://account-d.docusign.com/oauth/token",req,resp)
If (success = 0) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

Debug.Print "response status = " & resp.StatusCode
If (resp.StatusCode <> 200) Then
    Debug.Print resp.BodyStr
    Debug.Print "Failed."
Else
    ' Save the access token to a file for use in subsequent requests..
    ' (Or you may simply persiste the access token in memory for your applicaton to use for subsequent REST API calls..)
    success = resp.SaveBodyText(1,"qa_data/tokens/docusign.json")
    Debug.Print resp.BodyStr
    Debug.Print "Success."
End If