Visual Basic 6.0

Renew a DigiCert Certificate from an EST-enabled profile

See more Certificates Examples

Demonstrates how to renew a certificate from an EST-enabled profile in DigiCert​​®​​ Trust Lifecycle Manager. (The certificate must be within the renewal window configured in the certificate profile. The CSR must have same Subject DN values as the original certificate.) Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' The example below duplicates the following OpenSSL commands:
' 
' # Name of certificate as argument 1
' 
' # Make new key
' openssl ecparam -name prime256v1 -genkey -noout -out ${1}.key.pem
' 
' # Make csr
' openssl req -new -sha256 -key ${1}.key.pem -out ${1}.p10.csr -subj "/CN=${1}"
' 
' # Request new cert
' curl -v --cacert data/ca.pem --cert data/${1}.pem --key data/${1}.key.pem 
'     --data-binary @${1}.p10.csr -o ${1}.p7.b64 -H "Content-Type: application/pkcs10" https://clientauth.demo.one.digicert.com/.well-known/est/IOT/simplereenroll
' 
' # Convert to PEM
' openssl base64 -d -in ${1}.p7.b64 | openssl pkcs7 -inform DER -outform PEM -print_certs -out ${1}.pem

' ------------------------------------------------------------------------------------------------------------------

' Create a Fortuna PRNG and seed it with system entropy.
' This will be our source of random data for generating the ECC private key.
Dim fortuna As New ChilkatPrng
Dim entropy As String
entropy = fortuna.GetEntropy(32,"base64")
success = fortuna.AddEntropy(entropy,"base64")

Dim ec As New ChilkatEcc

' Generate a random EC private key on the prime256v1 curve.
Dim privKey As New PrivateKey
success = ec.GenKey("prime256v1",fortuna,privKey)
If (success <> 1) Then
    Debug.Print ec.LastErrorText
    Exit Sub
End If

' Create the CSR object and set properties.
Dim csr As New ChilkatCsr

' Specify your CN
csr.CommonName = "mysubdomain.mydomain.com"

' Create the CSR using the private key.
Dim bdCsr As New ChilkatBinData
success = csr.GenCsrBd(privKey,bdCsr)
If (success = 0) Then
    Debug.Print csr.LastErrorText
    Exit Sub
End If

' Save the private key and CSR to files.
success = privKey.SavePkcs8EncryptedPemFile("password","c:/temp/qa_output/ec_privkey.pem")

success = bdCsr.WriteFile("c:/temp/qa_output/csr.pem")

' ----------------------------------------------------------------------
' Now do the CURL request to POST the CSR and get the new certificate.

Dim http As New ChilkatHttp

Dim tlsClientCert As New ChilkatCert
success = tlsClientCert.LoadFromFile("data/myTlsClientCert.pem")
If (success = 0) Then
    Debug.Print tlsClientCert.LastErrorText
    Exit Sub
End If

Dim bdTlsClientCertPrivKey As New ChilkatBinData
success = bdTlsClientCertPrivKey.LoadFile("data/myTlsClientCert.key.pem")
If (success = 0) Then
    Debug.Print "Failed to load data/myTlsClientCert.key.pem"
    Exit Sub
End If

Dim tlsClientCertPrivKey As New PrivateKey
success = tlsClientCertPrivKey.LoadAnyFormat(bdTlsClientCertPrivKey,"")
If (success = 0) Then
    Debug.Print tlsClientCertPrivKey.LastErrorText
    Exit Sub
End If

success = tlsClientCert.SetPrivateKey(tlsClientCertPrivKey)
If (success = 0) Then
    Debug.Print tlsClientCert.LastErrorText
    Exit Sub
End If

success = http.SetSslClientCert(tlsClientCert)

http.RequireSslCertVerify = 1

' The body of the HTTP request contains the binary CSR.
Dim resp As New ChilkatHttpResponse
Dim url As String
url = "https://clientauth.demo.one.digicert.com/.well-known/est/IOT/simplereenroll"
success = http.HttpBd("POST",url,bdCsr,"application/pkcs10",resp)
If (success = 0) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

If (resp.StatusCode <> 200) Then
    Debug.Print "response status code = " & resp.StatusCode
    Debug.Print resp.BodyStr
    Debug.Print "Failed"
    Exit Sub
End If

' The response is the Base64 DER of the new certificate.
Dim myNewCert As New ChilkatCert
success = myNewCert.LoadFromBase64(resp.BodyStr)
If (success = 0) Then
    Debug.Print myNewCert.LastErrorText
    Debug.Print "Cert data = " & resp.BodyStr
    Debug.Print "Failed."
    Exit Sub
End If

success = myNewCert.SaveToFile("c:/temp/qa_output/myNewCert.cer")
If (success = 0) Then
    Debug.Print myNewCert.LastErrorText
    Debug.Print "Failed."
    Exit Sub
End If

Debug.Print "Success."