Visual Basic 6.0

Load .crl, Convert to XML, Get Revoked Serial Numbers and Dates

See more Certificates Examples

Load a binary .crl file (Certificate Revocation List), converts to XML, and then gets the revoked certificate serial numbers and revocation dates.

Note: This example requires Chilkat v9.5.0.77 or greater.

Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Load a binary .crl file.
Dim bdCrl As New ChilkatBinData
success = bdCrl.LoadFile("qa_data/crl/ca1.crl")
If (success <> 1) Then
    Debug.Print "Failed to load CRL file."
    Exit Sub
End If

Dim asn As New ChilkatAsn
success = asn.LoadBd(bdCrl)
If (success <> 1) Then
    Debug.Print asn.LastErrorText
    Exit Sub
End If

' Convert ASN.1 to XML and load into xml and re-emit for pretty printing..
Dim xml As New ChilkatXml
success = xml.LoadXml(asn.AsnToXml())
success = xml.SaveXml("qa_output/crl.xml")

' Use this online tool to generate parsing code from CRL XML: 
' Generate Parsing Code from XML

' Here's code to parse the XML.  This code was generated by the above tool,
' and then we modified it by removing unneeded code and changing some names
Dim i As Long
Dim count_i As Long
Dim tagPath As String
Dim j As Long
Dim count_j As Long
Dim k As Long
Dim count_k As Long

Dim revokedCertSerialHex As String
Dim dateRevoked As String

Dim dt As New CkDateTime

i = 0
count_i = xml.NumChildrenHavingTag("sequence")
Do While i < count_i
    xml.I = i

    j = 0
    count_j = xml.NumChildrenHavingTag("sequence[i]|sequence")
    Do While j < count_j
        xml.J = j

        k = 0
        count_k = xml.NumChildrenHavingTag("sequence[i]|sequence[j]|sequence")
        Do While k < count_k
            xml.K = k

            ' Get the revoked certificate's serial number in uppercase hex.
            revokedCertSerialHex = xml.GetChildContent("sequence[i]|sequence[j]|sequence[k]|int")
            Debug.Print "serial number: " & revokedCertSerialHex

            ' Get the date/time revoked.  It will be a string formatted as "YYMMDDhhmmssZ", such as "181023093028Z"
            dateRevoked = xml.GetChildContent("sequence[i]|sequence[j]|sequence[k]|utctime")

            ' Starting in Chilkat v9.5.0.77, date/time strings formatted as YYMMDDhhmmssZ can be parsed as follows:
            success = dt.SetFromTimestamp(dateRevoked)
            Debug.Print "date revoked: " & dt.GetAsRfc822(0)

            k = k + 1
        Loop
        j = j + 1
    Loop
    i = i + 1
Loop