Visual Basic 6.0

Azure Service Bus - Read Queued Message

See more Azure Service Bus Examples

Demonstrates read a message from an Azure Service Bus Queue. The message is received and removed from the queue. Visual Basic 6.0

Dim success As Long
success = 0

' Note: Requires Chilkat v9.5.0.65 or greater.

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Make the initial connection.
' A single REST object, once connected, can be used for many Azure Service Bus REST API calls.
' The auto-reconnect indicates that if the already-established HTTPS connection is closed,
' then it will be automatically re-established as needed.
Dim rest As New ChilkatRest
Dim bAutoReconnect As Long
bAutoReconnect = 1
success = rest.Connect("<yournamespace>.servicebus.windows.net",443,1,bAutoReconnect)
If (success <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

' ----------------------------------------------------------------------------------------------
' The code above this comment could be placed inside a function/subroutine within the application
' because the connection does not need to be made for every request.  Once the connection is made
' the app may send many requests..
' ----------------------------------------------------------------------------------------------

' Receive and delete a message from a queue named "gila";
Dim queueName As String
queueName = "gila"

' Let's load a previously computed SAS token and use it.
' See Azure Shared Access Signature for an example to genenerate an Azure SAS token.
Dim sbToken As New ChilkatStringBuilder
success = sbToken.LoadFile("qa_data/tokens/serviceBusSas.txt","utf-8")

' Tell the REST object to use the Azure Shared Access Signature for authorization.
success = sbToken.Prepend("SharedAccessSignature ")
success = rest.AddHeader("Authorization",sbToken.GetAsString())

' Build the path..
Dim sbPath As New ChilkatStringBuilder
success = sbPath.Append("/")
success = sbPath.Append(queueName)
success = sbPath.Append("/messages/head")

' Add timeout and api-version query parameters.
success = rest.AddQueryParam("timeout","20")
success = rest.AddQueryParam("api-version","2013-08")

' Use the DELETE HTTP verb to read the message at the head of the queue and remove it.
Dim sbResponseBody As New ChilkatStringBuilder
success = rest.FullRequestNoBodySb("DELETE",sbPath.GetAsString(),sbResponseBody)
If (success <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

Debug.Print "Response Status Code = " & rest.ResponseStatusCode

' Check for a success response.
If (rest.ResponseStatusCode <> 200) Then
    Debug.Print rest.LastRequestStartLine
    Debug.Print rest.LastRequestHeader
    Debug.Print sbResponseBody.GetAsString()
    Debug.Print "Failed."
    Exit Sub
End If

' If successful, the message is the contents of the response body.
Dim message As String
message = sbResponseBody.GetAsString()
Debug.Print "Dequeued message: " & message

Debug.Print "Success."