Classic ASP
SQS Create Queue

Creates a new SQS queue.
See SQS CreateQueue or detailed information.
Chilkat Classic ASP Downloads

Classic ASP
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set rest = Server.CreateObject("Chilkat.Rest")

' Connect to the Amazon AWS REST server.
' such as https://sqs.us-west-2.amazonaws.com/
bTls = 1
port = 443
bAutoReconnect = 1
success = rest.Connect("sqs.us-west-2.amazonaws.com",port,bTls,bAutoReconnect)

' Provide AWS credentials for the REST call.
set authAws = Server.CreateObject("Chilkat.AuthAws")
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
' the region should match our URL above..
authAws.Region = "us-west-2"
authAws.ServiceName = "sqs"

success = rest.SetAuthAws(authAws)

success = rest.AddQueryParam("Action","CreateQueue")
success = rest.AddQueryParam("QueueName","testQueue")
success = rest.AddQueryParam("Attribute.1.Name","VisibilityTimeout")
success = rest.AddQueryParam("Attribute.1.Value","40")

responseXml = rest.FullRequestNoBody("GET","/")
If (rest.LastMethodSuccess <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( rest.LastErrorText) & "</pre>"
    Response.End
End If

' A successful response will have a status code equal to 200.
If (rest.ResponseStatusCode <> 200) Then
    Response.Write "<pre>" & Server.HTMLEncode( "response status code = " & rest.ResponseStatusCode) & "</pre>"
    Response.Write "<pre>" & Server.HTMLEncode( "response status text = " & rest.ResponseStatusText) & "</pre>"
    Response.Write "<pre>" & Server.HTMLEncode( "response header: " & rest.ResponseHeader) & "</pre>"
    Response.Write "<pre>" & Server.HTMLEncode( "response body: " & responseXml) & "</pre>"
    Response.End
End If

' Examine the successful XML response.
set xml = Server.CreateObject("Chilkat.Xml")
success = xml.LoadXml(responseXml)
Response.Write "<pre>" & Server.HTMLEncode( xml.GetXml()) & "</pre>"

' A sample CreateQueue response:
' <CreateQueueResponse>
'     <CreateQueueResult>
'         <QueueUrl>
'             http://queue.amazonaws.com/123456789012/testQueue
'         </QueueUrl>
'     </CreateQueueResult>
'     <ResponseMetadata>
'         <RequestId>
'             7a62c49f-347e-4fc4-9331-6e8e7a96aa73
'         </RequestId>
'     </ResponseMetadata>
' </CreateQueueResponse>

%>
</body>
</html>