Classic ASP
Test Salesforce OAuth2 Access Token

Demonstrates how to make a simple Salesforce REST API call to test a previously obtained access token.
Chilkat Classic ASP Downloads

Classic ASP
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

' This example does the following:

' curl -X GET https://yourInstance.salesforce.com/services/oauth2/userinfo \
'      -H "Authorization: Bearer YOUR_ACCESS_TOKEN"

set http = Server.CreateObject("Chilkat.Http")

' Use the following online tool to generate HTTP code from a CURL command
' Convert a cURL Command to HTTP Source Code

' This example assumes the OAuth2 access token was previously fetched 
' and saved to a file.  See Get SalesForce OAuth2 Access Token via Authorization Flow

set json = Server.CreateObject("Chilkat.JsonObject")
success = json.LoadFile("qa_data/tokens/_salesforce.json")
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( "Failed to load OAuth2 access token.") & "</pre>"
    Response.End
End If

' Here's an example of the JSON:

' {
'   "access_token": "00D41000....uLZBpT6",
'   "refresh_token": "5Aep....25xdGgkrV",
'   "signature": "cjTbSc5DvcKpaMoRTzuQTJLb1tcMw8LEO01flq4aMD4=",
'   "scope": "refresh_token id",
'   "instance_url": "https://d41000000f8a0eak-dev-ed.my.salesforce.com",
'   "id": "https://login.salesforce.com/id/00D41000000F8A0EAK/005410000....xAAE",
'   "token_type": "Bearer",
'   "issued_at": "1738348388166"
' }

' Adds the "Authorization: Bearer YOUR_ACCESS_TOKEN" header.
http.AuthToken = json.StringOf("access_token")

' We want to build the following URL:  https://<instance_id>.salesforce.com/services/oauth2/userinfo
set sbUrl = Server.CreateObject("Chilkat.StringBuilder")
success = sbUrl.Append(json.StringOf("instance_url"))
success = sbUrl.Append("/services/oauth2/userinfo")

set sbResponseBody = Server.CreateObject("Chilkat.StringBuilder")
success = http.QuickGetSb(sbUrl.GetAsString(),sbResponseBody)
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( http.LastErrorText) & "</pre>"
    Response.End
End If

Response.Write "<pre>" & Server.HTMLEncode( "Response status code = " & http.LastStatus) & "</pre>"

set jsonResponse = Server.CreateObject("Chilkat.JsonObject")
success = jsonResponse.LoadSb(sbResponseBody)
jsonResponse.EmitCompact = 0
Response.Write "<pre>" & Server.HTMLEncode( jsonResponse.Emit()) & "</pre>"

' The expected JSON response is something like this:

' {
'   "sub": "005xxxxxxxxxxxx",
'   "name": "John Doe",
'   "preferred_username": "johndoe@example.com",
'   "email": "johndoe@example.com",
'   "profile": "https://na85.salesforce.com/005xxxxxxxxxxxx"
' ...
' ...
' }

%>
</body>
</html>