Classic ASP
IBM Cloud - Text to Speech - Synthesize Audio (GET)

Synthesizes text to audio that is spoken in the specified voice.
Chilkat Classic ASP Downloads

Classic ASP
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set http = Server.CreateObject("Chilkat.Http")

http.Login = "apikey"
http.Password = "my_apikey"
http.BasicAuth = 1

' Use your base URL shown in the credentials web page (below your apikey)
myBaseUrl = "https://api.us-south.text-to-speech.watson.cloud.ibm.com/instances/31941e96-7b89-4d56-8993-9cd8f18ec2d8"

set sbUrl = Server.CreateObject("Chilkat.StringBuilder")
success = sbUrl.Append(myBaseUrl)
success = sbUrl.Append("/v1/synthesize?accept=ACCEPT_TYPE&voice=CHOSEN_VOICE&text=TEXT_TO_SYNTHESIZE")

' Choose "audio/wav" for the output file type.
numReplaced = sbUrl.Replace("ACCEPT_TYPE",http.UrlEncode("audio/wav"))
' See the choices for voices at https://cloud.ibm.com/apidocs/text-to-speech#synthesize-audio-get
numReplaced = sbUrl.Replace("CHOSEN_VOICE","en-US_MichaelVoice")
textToSynthesize = "When life gives you lemons, order the lobster tail."
numReplaced = sbUrl.Replace("TEXT_TO_SYNTHESIZE",http.UrlEncode(textToSynthesize))

' Send the GET to synthesize the voice.
' The response file will be contained in bdResponseBody
set bdResponseBody = Server.CreateObject("Chilkat.BinData")
success = http.QuickGetBd(sbUrl.GetAsString(),bdResponseBody)
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( http.LastErrorText) & "</pre>"
    Response.End
End If

respStatusCode = http.LastStatus
Response.Write "<pre>" & Server.HTMLEncode( "response status code = " & respStatusCode) & "</pre>"

If (respStatusCode = 200) Then
    success = bdResponseBody.WriteFile("qa_output/lobster.wav")
    Response.Write "<pre>" & Server.HTMLEncode( "Success!") & "</pre>"
Else
    Response.Write "<pre>" & Server.HTMLEncode( bdResponseBody.GetString("utf-8")) & "</pre>"
End If


%>
</body>
</html>