(Classic ASP) Secure FTP with Client Certificate

Chilkat FTP2 provides the ability to use a client certificate with secure FTP (implicit or explicit SSL/TLS). This example demonstrates how to load a certificate from a .pfx and use it as the client-side SSL cert. Note: Client-side certificates are only needed in situations where the server demands one.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Ftp2")
set ftp = Server.CreateObject("Chilkat.Ftp2")

ftp.Hostname = "ftp.***.com"
ftp.Port = 21
ftp.Username = "test"
ftp.Password = "test"

' This example will use explict TLS/SSL.
' Establish an explicit secure channel after connection
' on the standard FTP port 21.
ftp.AuthTls = 1

' The Ssl property is for establishing an implicit SSL connection
' on port 990.  Because this example uses explicit SSL, it 
' should remain 0.
ftp.Ssl = 0

' Load a certificate from a .pfx
' A PFX may contain several certs, including the certificates
' in a chain of authority.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.CertStore")
set certStore = Server.CreateObject("Chilkat.CertStore")

password = "***"
' Load the certs from a PFX into an in-memory certificate store:
success = certStore.LoadPfxFile("chilkat.pfx",password)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( certStore.LastErrorText) & "</pre>"
    Response.End
End If

' Find the exact cert we'll use:

' cert is a Chilkat.Cert
Set cert = certStore.FindCertBySubject("Chilkat Software, Inc.")
If (certStore.LastMethodSuccess = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( "Certificate not found!") & "</pre>"
    Response.End
End If

' Use this certificate for our secure (SSL/TLS) connection:
success = ftp.SetSslClientCert(cert)

' Connect and login to the FTP server.  The connection is 
' made secure because of the AuthTls setting.
success = ftp.Connect()
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( ftp.LastErrorText) & "</pre>"
    Response.End
Else
    ' LastErrorText contains information even when
    ' successful. This allows you to visually verify
    ' that the secure connection actually occurred.
    Response.Write "<pre>" & Server.HTMLEncode( ftp.LastErrorText) & "</pre>"
End If

Response.Write "<pre>" & Server.HTMLEncode( "Secure FTP Channel Established!") & "</pre>"

' Do whatever you're doing to do ...
' upload files, download files, etc...

' .....
' .....

success = ftp.Disconnect()

%>
</body>
</html>